Comunicação entre Arduinos: I2C - Parte 2

Esse tutorial é a segunda parte do Tutorial Comunicação entre Arduinos: I2C - Parte 1. Se você ainda não viu, recomendamos que veja a Parte 1 do tutorial antes prosseguir.
Nessa segunda parte do tutorial a placa Slave estará conectada ao botão e, ao pressionar este botão, o estado do led conectado à placa Master será alterado. A placa Master trabalhará como o receptor e a placa slave como o emissor.

Para isso precisaremos de:

Confira na imagem ao lado como realizar as conexões de cada BlackBoard.

Agora que você já montou todo o circuito, é necessário programar cada placa com seu código. Neste momento, é importante que você verifique se está gravando a BlackBoard correta, por isso recomendamos que conecte e programe uma placa por vez. Desta forma você não irá se confundir com as portas COM.

Código para a BlackBoard Master (conectada ao LED):

/*
      RoboCore - Tutorial Comunicacao entre Arduinos: I2C - Parte 2
                                                           (Master)
                                                       (03/05/2015)

  Escrito por Marcelo Farias.

  Exemplo de como comunicar Arduinos utilizando o protocolo I2C.

  Altera o estado do LED conectado a placa Master quando o botao ligado
  a placa Slave for pressionado.

  Na placa Master foi utilizado um botao conectado ao pino 4, com o
  resistor de pullup interno da placa acionado e realizou-se um debounce
  em software. Na placa Slave foi utilizado um LED conectado ao pino 7.

  Referencias:
  Exemplo Debounce - https://www.arduino.cc/en/Tutorial/Debounce
  Tutorial Master Reader - https://www.arduino.cc/en/Tutorial/MasterReader
*/

#include "Wire.h"

#define ledPin 7 // numero do pino onde o LED esta conectado
  
// endereco do modulo slave que pode ser um valor de 0 a 255
#define slaveAdress 0x08

void setup() {
  // conecta ao barramento I2C com o endereço definido no myAdress (0x08)
  Wire.begin();

  pinMode(ledPin, OUTPUT);  // configura o pino do LED como saida
}

void loop() {
  // realiza uma requisicao de 1 byte de dados do modulo slave
  Wire.requestFrom(slaveAdress, 1);
  // verifica se existem dados para serem lidos no barramento I2C
  if (Wire.available()) {
    // le o byte recebido
    char received = Wire.read();

    // se o byte recebido for igual a 0, apaga o LED
    if (received == 0) {
      digitalWrite(ledPin, LOW);
    }

    // se o byte recebido for igual a 1 acende o LED
    if (received == 1) {
      digitalWrite(ledPin, HIGH);
    }
  }
}

Código para a BlackBoard Slave (conectada ao botão):

/*
      RoboCore - Tutorial Comunicacao entre Arduinos: I2C - Parte 2
                                                           (Master)
                                                       (03/05/2015)

  Escrito por Marcelo Farias.

  Exemplo de como comunicar Arduinos utilizando o protocolo I2C.

  Altera o estado do LED conectado a placa Master quando o botao ligado
  a placa Slave for pressionado.

  Na placa Master foi utilizado um botao conectado ao pino 4, com o
  resistor de pullup interno da placa acionado e realizou-se um debounce
  em software. Na placa Slave foi utilizado um LED conectado ao pino 7.

  Referencias:
  Exemplo Debounce - https://www.arduino.cc/en/Tutorial/Debounce
  Tutorial Master Reader - https://www.arduino.cc/en/Tutorial/MasterReader
*/

#include "Wire.h" // inclui a biblioteca Wire

#define buttonPin 4 // numero do pino onde o botao esta conectado
  
// endereco do modulo slave que pode ser um valor de 0 a 255
#define myAdress 0x08 

boolean buttonState;             // estado atual do botao
boolean lastButtonState = LOW;   // valor da ultima leitura do botao
boolean ledState = HIGH;         // estado atual do LED

// as variaveis a seguir sao do tipo long por conta que o tempo, medido 
// em milessegundos alcancara rapidamente um numero grande demais para 
// armazenar em uma variavel do tipo int

// tempo da ultima modificacao do estado do LED
unsigned long lastDebounceTime = 0;

// tempo de debounce; aumentar se o LED oscilar; espera-se que o LED acenda
// apenas se o botao for pressionado por mais de 50ms
unsigned long debounceDelay = 50;    

void setup() {
  Wire.begin(myAdress); // ingressa ao barramento I2C
  Wire.onRequest(requestEvent); // registra um evento para tratar requisicoes
  
  // configura o pino do botao como entrada com resistor de pullup interno
  pinMode(buttonPin, INPUT_PULLUP);
}

void loop() {
  // le o estado do botao e salva em uma variavel local
  int reading = digitalRead(buttonPin);

  // verifica se voce apenas apertou o botao (i.e. se a entrada foi de LOW 
  // to HIGH), e se ja esperou tempo suficiente para ignorar qualquer ruido

  // se a entrada foi alterada devido ao ruido ou botao ter sido pressionado:
  if (reading != lastButtonState) {
    // reseta o tempo do debounce
    lastDebounceTime = millis();
  }
  
  if ((millis() - lastDebounceTime) > debounceDelay) {
    // qualquer que seja a leitura atual, ela se manteve por um tempo maior
    // que o nosso debounce delay, então atualizemos o estado atual:

    // se o estado do botao foi alterado:
    if (reading != buttonState) {
      buttonState = reading;

      // apenas altera o estado do LED se o novo estado do botao e HIGH
      if (buttonState == HIGH) {
        ledState = !ledState;
      }
    }
  }
  // salva a leitura. No proximo laco este sera o ultimo 
  // estado do botao (lastButtonState)
  lastButtonState = reading;
}

// rotina para tratamento de requisicoes
// executada quando o mestre faz uma requisicao no barramento para
// o endereco desta placa, definido como 'myAdress'
void requestEvent(){
  // envia o estado que o led deve assumir
  Wire.write(ledState);
}

Agora basta alimentar ambas as placas que tudo deve funcionar perfeitamente. Aperte o botão da BlackBoard Slave e o LED conectado a placa Master deve acender. Se você apertar novamente o mesmo deve apagar. Agora você já sabe como enviar ou fazer requisições de mensagens utilizando o protocolo de comunicação I2C.

Comentários

Para fazer comentários é necessário estar logado. Efetuar login.

Você ainda nao é cadastrado? Cadastre-se agora!

mrpro77
date

Enviado 2022-06-29 03:49:46

Bom dia Equipe,
Depois de muita dedicação, consegui efetuar todas as comunicações perfeitamente, enviando os dados de  temperatura e umidade e a Luminosidade usando  a placa ROBOCORE IoT, como escravo e o Arduino Mega ADK, como Master, as recomendações e tutoriais indicados por vocês foram essenciais.
Valeu,  Muito obrigado.

luan.ferreira
date

Enviado 2022-06-29 09:01:47
mrpro77

Olá! Queremos lhe dar os nossos parabéns por não desistir na primeira dificuldade encontrada. Aliás, ficamos felizes em saber que participamos do seu aprendizado, mas gostaríamos de ressaltar que a sua dedicação e estudo, foram essenciais para a realização desse projeto. Para finalizar, esperamos continuar fazendo parte do seu aprendizado, seja por meio dos nossos Kits ou por meio de algum suporte técnico. Sendo assim, em caso de problemas ou dúvidas, entre em contato conosco.

mrpro77
date

Enviado 2022-05-22 19:28:00

Boa noite equipe, 
Estive estudando os códigos sugeridos, 
https://docs.espressif.com/projects/arduino-esp32/en/latest/api/i2c.html
https://www.robocore.net/tutoriais/60, para fazer a comunicação entre o Arduino  Mega ADK (MASTER) + Arduino UNO (SLAVE) e ROBOCORE IoT DEV1 (SLAVE), e a comunicação parece estar funcionando de maneira não satisfatória,  os dois ARDUINOS estão funcionando bem mas a placa do ESP32 não esta funcionando, porém não esta travando o processamento, posso colocar o exemplo de código aqui ?para pedir uma  ajuda, Muito Obrigado.

 Valeu pessoal   Boa Semana.

Giovanni5

Enviado 2022-05-23 08:59:45
mrpro77

Você utilizou um conversor de nível lógico entre o ESP32 e o barramento I2C das demais placas Arduino? Como o luan.ferreira informou anteriormente, isso é necessário para compatibilizar as tensões operacionais da placa, para que elas possam se comunicar corretamente. Além disso, o endereço I2C das placas que estão operando como "slave" estão diferentes? Vale lembrar que cada "slave" deve ter um endereço I2C único para que possa ser feita uma requisição separadamente pela placa "master".

Giovanni5

Enviado 2022-05-23 09:01:09
mrpro77

Infelizmente não trabalhamos com consultoria ou desenvolvimento de projetos e códigos, portanto não temos como ajudá-lo muito além destas dicas. Se quiser, você pode postar o seu código no nosso "Fórum" https://www.robocore.net/modules.php?name=Forums), explicando as dúvidas e dificuldades que está tendo, para que outros usuários mais experientes possam te ajudar.

mrpro77
date

Enviado 2022-05-16 02:39:57

Bom dia equipe,
  Eu, montei o exemplo acima com o Arduino Mega ADK, como master eo Arduino Uno como slave e funcionou bem, e usei também o componente TCA9548A, fazendo a comunicação pois tenho também, 2 Display Oled, e mais dois Lcd 20X4, e tentei ligar a Placa do IoT Devkit v1, e não consegui conforme foi mencionado no post abaixo, eu preciso que as variáveis, informadas de temperatura e umidade fornecidas pela placa da Robocore, seja lida pelo Arduino Mega e mostrada no Lcd, enfim o ESP32 da placa da Robocore precisa trabalhar como slave e não estou conseguindo. Por favor, poderia me ajudar

luan.ferreira
date

Enviado 2022-05-16 09:53:36
mrpro77

Olá! Conforme mencionado no comentário abaixo, para o ESP32 trabalhar com slave, será necessário modificar o código de acordo com a sua aplicação, mas não temos um tutorial para isso. Se for mais fácil, você pode rever a logica da sua aplicação para que o ESP32 atue como master, já que o código deste tutorial deve compilar diretamente para o ESP32, e só será necessário adaptá-lo para o envio das variáveis que deseja.

Francois

Enviado 2022-05-16 10:38:45
mrpro77

Complementando a resposta do @luan.ferreira, apesar de ainda não haver um tutorial sobre a comunicação I2C usando pelo menos um ESP32, você pode se basear na documentação do fabricante na página a seguir: https://docs.espressif.com/projects/arduino-esp32/en/latest/api/i2c.html

mrpro77
date

Enviado 2022-05-09 18:56:27

Boa noite equipe,
   Sim eu preciso que o esp32 trabalhe como slave, o Arduino Mega vai ler os dados fornecidos por ela,  o conversor vem com esquema de ligação ?  (https://www.robocore.net/regulador-de-tensao/conversor-de-nivel-logico ),  as adaptações no código são muito complexas ?, Valeu pessoal muito obrigado.

luan.ferreira
date

Enviado 2022-05-10 10:14:30
mrpro77

Olá! As alterações no código não devem ser muito complexas, mas isso vai depender da sua aplicação. Sobre a ligações do conversor de nível lógico, infelizmente não temos um esquema elétrico específico para este uso, porém você pode usar como base o tutorial “PROIoT - Introdução à Comunicação via HTTP” ( https://www.robocore.net/tutoriais/proiot-introducao-comunicao-http ), nesse tutorial é mostrado como ler o sensor DHT11 pelo no NodeMCU ESP8266-12 V2 usando o conversor de nível lógico.

mrpro77
date

Enviado 2022-05-08 19:36:35

Boa noite equipe ROBOCORE,  estou desenvolvendo um projeto e gostaria de saber se os exemplos acima, poderá ser usado entre a placa do ROBOCORE IoT devkit e entre o Arduino Mega ?
 Estou com dificuldades de fazer eles funcionar. 
  Valeu Boa semana.

luan.ferreira
date

Enviado 2022-05-09 10:35:38
mrpro77

Olá! A princípio, com esse tutorial só será possível fazer com que a placa ESP32 (placa do IoT DevKit) trabalhe como master, porém se você deseja que a placa ESP32 trabalhe como slave, você terá que fazer algumas adaptações no código. Vale dizer que, como o  ESP32 e a Mega operam com tensões distintas, é recomendado usar um conversor de nível lógico, como o Conversor de Nível Lógico RC ( https://www.robocore.net/regulador-de-tensao/conversor-de-nivel-logico ), por exemplo.

neide.jmoliveira
date

Enviado 2022-03-04 09:24:51

Bom dia !  Estou com um problema, quando  vou transferir o programa para placa robo core a porta não abre ,tem not que abre mas tenha note que não abre .
Você pode me ajudar?

Giovanni5

Enviado 2022-03-04 09:51:34
neide.jmoliveira

Se a placa funciona em alguns computadores e outros não, é necessário verificar se esses computadores em que ela não é reconhecida estão com o driver da placa corretamente instalado (https://www.robocore.net/tutoriais/instalacao-driver-da-blackboard), e testar o reconhecimento da placa com outros cabos e portas USB (preferencialmente USB 2.0, e sem HUBs USB).

luizvictorba
date

Enviado 2022-02-21 18:44:32

Olá, Consigo enviar uma array entre dois arduinos por meio do i2c?

Giovanni5

Enviado 2022-02-22 08:10:45
luizvictorba

Sim, é possível enviar um vetor por I2C, e basta utilizar um laço "for()" para poder enviar todas as variáveis do vetor.

mateusalvessil23
date

Enviado 2021-11-10 09:00:29

É possível eu usar um sensor digital em um arduino sem o protocolo I2C?

detoledo.victor
date

Enviado 2021-11-10 10:00:28
mateusalvessil23

Sim existem diversos sensores digitais que não fazem uso do protocolo I2C, muitos utilizam protocolo SPI ou até mesmo o protocolo one wire, dentre outros. Também tem alguns que podem ser lidos até mesmo sem um protocolo de comunicação. Caso o seu sensor seja protocolo I2C porém a sua placa não possui hardware nativo para integração com o mesmo, é necessário utilizar um conversor de I2C para o protocolo desejado.

gabrieleliasmarques
date

Enviado 2021-05-30 18:25:42

Boa noite!
Consigo executar um relê serial de um arduino slave?
Se sim, qual o comando para isso?

Giovanni5

Enviado 2021-05-31 08:16:31
gabrieleliasmarques

Sim, você pode controlar um Relé Serial no "escravo" através da comunicação I2C, mas os comandos para isso vão depender um pouco da lógica que deseja implementar. Você pode, por exemplo, aproveitar o botão já utilizado no "mestre" deste tutorial, para acionar um dos relés do módulo, como foi feito com o LED, aproveitando as funções da biblioteca do módulo (https://github.com/RoboCore/SerialRelay).

fcarlosrodrigues
date

Enviado 2019-07-04 11:29:58

Olá,
Também estou buscando conectar vários (10 a 15) arduinos entre si, pensei de usar o protocolo i2c, (porém seria necessário endereçar os escravos para solicitação de leitura e para distinguir as leituras dos sensores), teria um exmplo desse tipo de comunicação ?
Muito obrigado!
 Abraço!

Giovanni5

Enviado 2019-07-04 11:54:59
fcarlosrodrigues

Infelizmente não temos ainda um exemplo pronto para uma comunicação I2C com mais escravos. Entretanto, esse tutorial é um ótimo exemplo para entender como realizar requisições e enviar informações entre mestre e escravos através deste protocolo.