Alarme Beba Água

Projeto

Esquecer de tomar água durante o trabalho? Não mais. Com a ajuda de componentes eletrônicos e programação personalizada, manter-se hidratado enquanto realiza suas atividades diárias fica fácil!?

View this post on Instagram

A post shared by RoboCore Tecnologia (@robocore)

Lista de materiais

Circuito

Para realizarmos esse projeto, montamos um circuito como o mostrado abaixo.

Descricao Breve da Imagem — Circuito de Exemplo

Código

O código abaixo foi desenvolvido para a nossa aplicação, e por isso, dependendo do seu projeto, pode ser que seja necessário algumas adaptações.

/*******************************************************************************
  RoboCore - Projeto Alerme Beba Agua (V1.0)

  Exemplo de aplicacao usando uma BlackBoard Edge e um Modulo de Gravacao 
  e Reproducao de Audio, para lembrar os desidratados a tomarem agua! haha

  Copyright 2024 RoboCore.
  Escrito por Vini (15/04/2024).

  This program is free software: you can redistribute it and/or modify
  it under the terms of the GNU General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version (<https://www.gnu.org/licenses/>).
*******************************************************************************/

// Bibliotecas
#include <WiFi.h>
#include "time.h"
#include "RoboCore_MMA8452Q.h"

// Objeto de leitura do acelerometro
MMA8452Q acel;

// Variaveis para conexao Wi-Fi
const char* ssid     = "sua-rede-aqui";
const char* password = "senha-da-rede";

// Variaveis para conectar no servidor NTP
const char* ntpServer = "pool.ntp.org";
const long  gmtOffset_sec = -3L * 60L * 60L; // -3 horas de diferença do GMT
const int   daylightOffset_sec = 0;

// Horarios para alerta de beber agua
int hoursToNotify[10] = {8, 9, 10, 11, 12, 13, 14, 15, 16, 17}; // Altere como desejar

// Pino LED na Edge
const int edge_led = 27;

// Flag para saber se ja houve notificacao nessa hora
int lastHourNotified = 0;

void setup() {

  // Inicializacao do monitor serial
  Serial.begin(115200);

  // Connecta no Wi-Fi
  Serial.print("Conectando na rede: ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("Conectando");

  // Inicie e obtenha a hora
  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    Serial.println("Erro na conexão do servidor NTP");
  }

  // Desconecta o Wi-Fi
  WiFi.disconnect(true);
  WiFi.mode(WIFI_OFF);

  // Inicia o acelerometro
  acel.init();

  // Configura o pino do LED como saida
  pinMode(edge_led, OUTPUT);

}


void loop() {

  // Confere se a leitura atual do RTC e uma das horas configuradas no codigo
  int hourNow = checkHour();
  for (int index = 0; index < sizeof(hoursToNotify) / sizeof(int); index++) {
    if (hourNow == hoursToNotify[index]) {
    
      // Notificacao sera realizada uma vez por hora apenas, e so para se placa for virada.
      if (lastHourNotified != hourNow) {
        acel.read(); // Faz a leitura do acelerometro
        if (acel.y > 0.50) {
          // Os tempos de delay irao variar conforme o que voce gravar no modulo de gravacao de som
          digitalWrite(edge_led, HIGH);
          delay(2100);
          digitalWrite(edge_led, LOW);
          delay(250);

        } else {
          digitalWrite(edge_led, LOW);
          lastHourNotified = hourNow;
        }
      }
    }
  }

}

// Funcao para realizar a leitura de hora do RTC
int checkHour() {
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    Serial.println("Falha ao obter tempo");
    return 0;
  }
  char timeHour[3];
  strftime(timeHour, 3, "%H", &timeinfo);
  int hourNow = atoi(timeHour);
  return hourNow;
}