Primeiros Passos com o DS18B20

Introdução

Você já pensou em fazer um projeto que tinha a necessidade de medir a temperatura de algum ambiente, mas se deparou com um ambiente molhado? Então hoje você irá conhecer o sensor DS18B20 à prova d'água. Nesse tutorial você irá aprender a fazer a medição de temperatura de maneira simples e utilizando a sua BlackBoard.

O sensor DS18B20 à prova d'água é recomendado para situações onde é necessário medir a temperatura em ambientes úmidos. Também existe a possibilidade de ele ficar submerso, já que ele possui um cabo envolto de PVC e uma ponta de aço inox, o que facilita a utilização sem medo de danificá-lo. Uma outra boa vantagem desse sensor é que, caso você tenha a necessidade de medir a temperatura em uma distância relativamente afastada de sua BlackBoard, por ele utilizar o protocolo OneWire (criado pela Dallas Semiconductor), é possível realizar a leitura sem ter problemas com interferências causadas pela distância. Além disso, esse protocolo tem como diferencial o fato de utilizar apenas um cabo de comunicação, assim utilizando somente um pino de sua BlackBoard.

Lista de Materiais

Lista completa de produtos

comprar

BlackBoard UNO R3

R$ 94,90 no PIX

Cabo USB AB 1.50m

R$ 10,35 no PIX

Sensor de temperatura DS18B20 - À Prova de Água

R$ 11,40 no PIX

Protoboard 400 Pontos

R$ 6,55 no PIX

WorkPlate 400 - Preta

R$ 14,15 no PIX

Módulo Relé 5V - Relé Metaltex

R$ 9,97 no PIX

Resistor 10kΩ - Pacote com 10 unidades

R$ 0,71 no PIX

Jumpers Macho-Macho x40 Unidades

R$ 7,50 no PIX

Jumpers Macho-Fêmea x40 Unidades

R$ 7,50 no PIX

Primeiros Passos

Em um primeiro momento, vamos fazer uma leitura simples de temperatura utilizando o sensor DS18B20 com a BlackBoard.

Circuito

Monte o circuito conforme a imagem abaixo. Se necessário, descasque a ponta dos cabos do sensor para fazer a ligação em sua protoboard, desconsiderando o cabo branco, já que o sensor que você irá utilizar tem apenas 3 cabos (preto, vermelho e amarelo).

Programação

Biblioteca

Para começar é necessário fazer a instalação de duas bibliotecas para a leitura dos dados do sensor. Na sua Arduino IDE, clique em Sketch, depois vá até "Incluir Biblioteca" e entre em "Gerenciar Bibliotecas". Feito isso, digite no campo de pesquisa o nome das bibliotecas, "DallasTemperature" e "OneWire", e selecione para realizar instalação como nas imagens abaixo.

Resultados de Pesquisa para a Biblioteca DallasTemperature

Resultados de Pesquisa para a Biblioteca OneWire

Código

/********************************************************************
* Leitura do sensor de temperatura DS18B20 (v1.0).
*
* Realiza a leitura da temperatura utilizando sensor DS18B20.
* Apos a leitura, no monitor serial ira imprimir os dados lidos.
*
* Copyright 2019 RoboCore.
* Escrito por Renan Piva (10/04/2019).
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version (<https://www.gnu.org/licenses/>).
*****************************************************************************/

// Inclusao das bibliotecas
#include <OneWire.h>
#include <DallasTemperature.h>

const int PINO_ONEWIRE = 12; // Define pino do sensor
OneWire oneWire(PINO_ONEWIRE); // Cria um objeto OneWire
DallasTemperature sensor(&oneWire); // Informa a referencia da biblioteca dallas temperature para Biblioteca onewire
DeviceAddress endereco_temp; // Cria um endereco temporario da leitura do sensor

void setup() {
  Serial.begin(9600); // Inicia a porta serial
  Serial.println("Medindo Temperatura"); // Imprime a mensagem inicial
  sensor.begin(); ; // Inicia o sensor
}
  
void loop() {
  sensor.requestTemperatures(); // Envia comando para realizar a conversão de temperatura
  if (!sensor.getAddress(endereco_temp,0)) { // Encontra o endereco do sensor no barramento
    Serial.println("SENSOR NAO CONECTADO"); // Sensor conectado, imprime mensagem de erro
  } else {
    Serial.print("Temperatura = "); // Imprime a temperatura no monitor serial
    Serial.println(sensor.getTempC(endereco_temp), 1); // Busca temperatura para dispositivo
  }
  delay(1000);
}

Entendendo o Código

A primeira seção do código consiste apenas em adicionar as duas bibliotecas. Após as inclusões, definimos o pino no qual o sensor está conectado (const int PINO_ONEWIRE = 12). Também definimos algumas variáveis para serem usadas com as bibliotecas. Com OneWire oneWire(PINO_ONEWIRE) indicamos que o pino declarado é usado para uma comunicação OneWire. Já com DallasTemperature sensor(oneWire) indicamos que o sensor DS18B20 (sensor) deve usar a comunicação declarada anteriormente. Finalmente, a última linha, DeviceAddress endereco_temp, declara uma variável auxiliar que representa o endereço do sensor no barramento OneWire (afinal, esse protocolo permite o uso de diversos dispositivos no mesmo barramento).

Na função setup() configuramos a comunicação serial e inicializamos o sensor, conforme o trecho a seguir.

Serial.begin(9600);	// Inicia a porta serial
Serial.println("Medindo Temperatura");
sensor.begin();	// Inicia o sensor

E no final temos a parte que determina o intervalo de tempo entre cada leitura e o tratamento da leitura do sensor.

if (!sensor.getAddress(endereco_temp, 0)) // Encontra o endereco de um determinado sinal no barramento
  Serial.println("SENSOR NAO CONECTADO "); // Caso sensor nao esteja conectado,imprime mensagem de erro
} else {
  Serial.print("Temperatura = "); // Imprime a temperatura no monitor serial
  Serial.println(sensor.getTempC(endereco_temp), 1); // Busca temperatura para dispositivo
}

A função sensor.requestTemperature() inicia a leitura do sensor, que encaminha os dados de temperatura para sua BlackBoard. A função getAddress() verifica se um sensor válido está presente na linha, por isso a usamos para exibir uma mensagem de erro. Por fim, a função getTempC() retorna a temperatura em graus Celsius, para ser impressa no monitor serial.

O Que Deve Acontecer

Feito o upload para sua placa, abra o monitor serial, verifique se ele está em 9600 bps, e veja que a leitura da temperatura do seu sensor aparecerá na tela.

Exibindo a Temperatura no Monitor Serial — Exibição da Temperatura no Monitor Serial

Controle de Temperatura com Relé

O bacana é que, em algumas situações, você quer adicionar componentes para deixar seu projeto mais funcional. Vamos adicionar alguns componentes para controlar uma situação em que seja necessário ligar algo para esfriar o ambiente caso a temperatura esteja acima do desejado.

Circuito

Adicionamos ao circuito montado anteriormente um relé, agora pensando que você terá que ligar um dispositivo que vai resfriar o ambiente onde o sensor está, caso esteja muito quente. No exemplo abaixo iremos demonstrar utilizando um ventilador.

Como na imagem acima, você terá que fazer a ligação da carga com o relé utilizando os pinos NA e C para que seu dispositivo funcione. Dessa forma, o cabo que está no pino C será ligado direto na tomada (neutro) onde você irá ligar o ventilador e o pino NA será utilizado para a carga do dispositivo, deixando apenas o segundo terminal do dispositivo para ser ligado na rede elétrica (fase).

Atenção: antes de ligar a alimentação 110V/220V, verifique se todas as conexões estão feitas corretamente e se o cabo de alimentação está bem isolado. Nós da RoboCore não nos responsabilizamos por danos à rede elétrica ou à integridade física do praticante, portanto tenha muito cuidado antes de iniciar ou consulte um profissional da área.

Código

Após a montagem de seu circuito, carregue o código abaixo.

/********************************************************************
* Controle de temperatura com sensor DS18B20 (v1.0)
*
* Usando um rele para acionar um dispositivo para controle de temperatura do ambiente
* Caso a temperatura esteja elevada, um dispositivo sera acionado pelo rele.
*
* Copyright 2019 RoboCore.
* Escrito por Renan Piva (10/04/2019).
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version (<https://www.gnu.org/licenses/>).
*******************************************************************************/

// Inclusao da bibliotecas 
#include <OneWire.h>
#include <DallasTemperature.h>

const int PINO_ONEWIRE = 12; // Define pino do sensor
const int PINO_RELE = 13; // Informa pino do rele
OneWire oneWire(PINO_ONEWIRE); // Cria um objeto OneWire
DallasTemperature sensor(&oneWire); // Informa as referencias da biblioteca dallas temperature para biblioteca onewire
DeviceAddress endereco_temp; // Cria um endereco temporario da leitura do sensor

void setup() {
  Serial.begin(9600); // Inicia a porta serial
  Serial.println("Medindo temperatura"); // Imprime a mensagem inicial
  sensor.begin(); // Inicia o sensor
  pinMode(PINO_RELE, OUTPUT);
}
  
void loop() {
  sensor.requestTemperatures(); // Envia comandos para realizar uma conversao de temperatura
  if (!sensor.getAddress(endereco_temp,0)){ // Encontra o endereco de um determinado sinal no barramento
    Serial.println("SENSOR NAO CONECTADO"); // Sensor nao conectado imprime mensagem de erro
  } else {
    float temperatura = sensor.getTempC(endereco_temp);
    Serial.print("Temperatura = "); // Caso o sensor for reconhecido apresenta as infomacoes
    Serial.println(temperatura, 1);
  
    if (temperatura >= 30){ // Caso temperatura ultrapasse os 30 graus Celsius aciona o rele
      digitalWrite(PINO_RELE, HIGH); // Rele acionado
    } else  {
      digitalWrite(PINO_RELE, LOW); // Temperatura abaixo de 30 graus Celsius desliga o rele
    }
    delay(1000); // Espera 1 segundo para repetir a leitura
  }
}

Entendendo o Código

Foi feita uma adição no código anterior para acionar um relé quando a temperatura ultrapassar 30 °C. Este relé, por sua vez, irá acionar um ventilador para resfriar até essa temperatura.

if (temperatura >= 30) { // Caso temperatura ultrapasse os 30 graus Celsius, aciona o rele
  digitalWrite(rele, HIGH); // Rele acionado
} else {
  digitalWrite(rele, LOW);  // Quando a temperatura esta abaixo de 30 graus Celsius desliga o rele
}

O Que Deve Acontecer

Feitas todas as verificações, alimente sua Blackboard, abra o monitor serial e observe os valores exibidos. Para esquentar o sensor, utilize sua mão, fechando-a com o componente dentro, e você vai perceber que a temperatura irá subir. A partir do momento em que ela chegar em 30 °C, o relé irá acionar o ventilador que irá começar a climatizar o ambiente.

Acionar um Dispositivo para Esfriar o Ambiente

Indo Além

Caso você queira esquentar o ambiente e tenha que utilizar um aquecedor, você deve apenas alterar o código de forma a ligar o seu dispositivo se a temperatura ficar abaixo de 10 °C, por exemplo. Caso utilize um aquecedor, verifique antes se o módulo relé usado é o suficiente para suportar a corrente elétrica necessária. Para modificar o código você pode alterar o laço if para algo como o trecho a seguir.

if (temperatura <= 10) { // Caso temperatura caia para menos que 10 graus Celsius aciona o rele
  digitalWrite(rele, HIGH); // Rele acionado
} else {
  digitalWrite(rele, LOW); // Voltando a temperatura abaixo de 10 graus Celsius desliga o rele
}

Agora é inovar e tentar criar situações em que você possa utilizar o sensor DS18B20 à prova d'água da melhor maneira possível. Esperamos que esse tutorial tenha te ajudado a criar o projeto de forma tranquila e qualquer dúvida ou sugestão é só comentar abaixo.

Solução de Problemas

Mensagem de erro "sensor nao conectado"

Caso o sensor não esteja sendo reconhecido, verifique as conexões.