Controle de Mídia com BlackBoard Wisdom

This tutorial is not available in English

Projeto

Cansado(a) de lavar a louça e não poder trocar a música que está tocando por estar com a mão molhada? Seus problemas acabaram! Neste projeto mostramos como fazer um controle remoto sem fio via bluetooth para seu celular Android ou computador. Ao executar este código sua BlackBoard Wisdom se transforma num poderoso controlador de mídia, com a qual você poderá trocar a música sem encostar no seu dispositivo, e ainda poderá aumentar ou diminuir o volume usando o potenciômetro deslizante da placa!

Lista de materiais

1x BlackBoard Wisdom
1x Cabo USB Micro B 80cm

Circuito

Para esse projeto, usamos as funcionalidades da própria placa!

Código

O código abaixo foi desenvolvido para a nossa aplicação, e por isso, dependendo do seu projeto, pode ser que seja necessário algumas adaptações.

/*******************************************************************************
* Controle de Midia com BlackBoard Wisdom
* Controle o som e a reproducao de midias atraves de Bluetooth.
*******************************************************************************/

#include <BleKeyboard.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <SparkFun_APDS9960.h>

const int DISPLAY_WIDTH = 128;
const int DISPLAY_HEIGHT = 64;
const int RESET_DISPLAY = -1;
const int DISPLAY_ADDRESS = 0x3C;

const uint8_t PIN_SLIDER = 39;
const uint8_t LEDS[] = {13, 4, 16, 17, 18, 19, 23};
const uint8_t STEP = 1;
const int MAXIMUM_SOUND_LEVEL = 15;
const unsigned long WAITING_TIME = 100; // 50 [ms]
unsigned long interval;

int currentVolume = 0;
int previousValue = -1;

Adafruit_SSD1306 briick_OLED(DISPLAY_WIDTH, DISPLAY_HEIGHT, &Wire, RESET_DISPLAY);
SparkFun_APDS9960 apds = SparkFun_APDS9960();
BleKeyboard bleKeyboard;

void setup()
{
  Serial.begin(115200);
  Serial.println("Iniciando BLE!");

  pinMode(PIN_SLIDER, INPUT);

  for (uint8_t led = 0; led < sizeof(LEDS); led++)
  {
    pinMode(LEDS[led], OUTPUT);
    digitalWrite(LEDS[led], LOW);
  }

  apds.init();
  apds.enableGestureSensor(false);

  bleKeyboard.begin();

  briick_OLED.begin(SSD1306_SWITCHCAPVCC, DISPLAY_ADDRESS);

  briick_OLED.clearDisplay();
  briick_OLED.display();
  briick_OLED.setTextColor(SSD1306_WHITE);
}

int readValue()
{
  return map(analogRead(PIN_SLIDER), 0, 4095, MAXIMUM_SOUND_LEVEL, 0);
}

void readGestures()
{
  if (apds.isGestureAvailable())
  {
    int gestures = apds.readGesture();

    if (gestures == DIR_LEFT)
    {
      bleKeyboard.write(KEY_MEDIA_PREVIOUS_TRACK);
    }
    if (gestures == DIR_RIGHT)
    {
      bleKeyboard.write(KEY_MEDIA_NEXT_TRACK);
    }
  }
}

void volumeControl(int value)
{
  if (value > currentVolume)
  {

    int steps = (value - currentVolume + STEP - 1) / STEP;
    for (int i = 0; i < steps; i++)
    {
      bleKeyboard.write(KEY_MEDIA_VOLUME_UP);
    }
  }
  else if (value < currentVolume)
  {

    int steps = (currentVolume - value + STEP - 1) / STEP;
    for (int i = 0; i < steps; i++)
    {
      bleKeyboard.write(KEY_MEDIA_VOLUME_DOWN);
    }
  }
  currentVolume = value;
}

void updateLEDBar(int value)
{
  int percentage = map(value, 0, MAXIMUM_SOUND_LEVEL, 0, 100);

  if (percentage > 0)
  {
    digitalWrite(LEDS[0], HIGH);
  }
  else
  {
    digitalWrite(LEDS[0], LOW);
  }

  if (percentage > 25)
  {
    digitalWrite(LEDS[1], HIGH);
  }
  else
  {
    digitalWrite(LEDS[1], LOW);
  }

  if (percentage > 50)
  {
    digitalWrite(LEDS[2], HIGH);
  }
  else
  {
    digitalWrite(LEDS[2], LOW);
  }

  if (percentage > 75)
  {
    digitalWrite(LEDS[3], HIGH);
  }
  else
  {
    digitalWrite(LEDS[3], LOW);
  }
}

void updateGraph(int value)
{
  if (interval < millis())
  {
    int numBars = 8;
    int barWidth = DISPLAY_WIDTH / numBars;

    int barHeight = map(value, 0, MAXIMUM_SOUND_LEVEL, 0, DISPLAY_HEIGHT);

    for (int i = 0; i < numBars; i++)
    {
      int barHeightModulated = random(0, barHeight);
      briick_OLED.fillRect(i * barWidth, DISPLAY_HEIGHT - barHeightModulated, barWidth - 1, barHeightModulated, SSD1306_WHITE);
    }

    briick_OLED.display();

    interval = millis() + WAITING_TIME;
  }
  briick_OLED.clearDisplay();
}

void loop()
{
  if (bleKeyboard.isConnected())
  {
    int sliderValue = readValue();

    readGestures();

    if (sliderValue != previousValue)
    {
      volumeControl(sliderValue);
      previousValue = sliderValue;
      delay(100);
    }

    updateGraph(sliderValue);
    updateLEDBar(sliderValue);
  }
}