IoT DevKit - 18. Central de Monitoramento por Bluetooth

/*******************************************************************************

* IoT DevKit - Central de Monitoramento Bluetooth (v1.0)

* 

* Codigo utilizado para realizar a leitura de todos os sensores do IoT DevKit, 

* e entao enviar essas leituras para o aplicativo Blynk do celular que estiver

* conectado ao ESP32 do kit.

* 

* Copyright 2020 RoboCore.

* Escrito por Giovanni de Castro (15/09/2020).

* Creditos - @francois - RoboCore

*          - @bijilbaji - Solucao proposta no topico #102 do GitHub

*            - (https://github.com/espressif/arduino-esp32/issues/102#issuecomment-611307887)

* 

* This program is free software: you can redistribute it and/or modify

* it under the terms of the GNU Lesser General Public License as published by

* the Free Software Foundation, either version 3 of the License, or

* (at your option) any later version (<https://www.gnu.org/licenses/>).

*******************************************************************************/

​

//Definicao das funcoes auxiliares para o Blynk

#define BLYNK_PRINT Serial

#define BLYNK_USE_DIRECT_CONNECT

​

//Inclusao das bibliotecas

#include <BlynkSimpleEsp32_BLE.h>

#include <BLEDevice.h>

#include <BLEServer.h>

#include <DHT.h>

#include "RoboCore_MMA8452Q.h"

#include <soc/sens_reg.h> //Biblioteca para a leitura dos registradores

//Declaracao da variavel que armazena a chave de autenticacao do aplicativo

const char CHAVE_AUTENTICACAO[] = "SUA-CHAVE-AUTENTICACAO-AQUI"; //Altere essa variavel com a chave de seu projeto

​

//Criacao do timer para a leitura do LDR, do DHT e do acelerometro

BlynkTimer timerLDR;

BlynkTimer timerDHT;

BlynkTimer timerACELEROMETRO;

​

// Attach virtual serial terminal to Virtual Pin "V1"

WidgetTerminal terminal(V1);

​

//Criacao do objeto "acelerometro" pela biblioteca "MMA8452Q"

MMA8452Q acelerometro;

​

//Definicao do pino conectado ao LDR

const int PINO_LDR = 15;

​

//Declaracao do pino conectado ao LED do kit

const int PINO_LED = 13;

​

//Declaracao do pino conectado ao sensor DHT no IoT DevKit

const int PINO_DHT = 12;

​

//Criacao do objeto DHT de acordo com o pino que ele esta conectado, e o seu modelo

DHT dht(PINO_DHT, DHT11); //Modelo de fabrica do IoT DevKit - DHT11

​

//Declaracao da variavel e da funcao para leitura do LDR

uint32_t adc_register; //Variavel para o registrador

int customARead(int); //Funcao para a leitura do sensor

​

//---------------------------------------------------------------------------------------

//Funcao para ler o LDR e enviar a leitura para o Blynk

void lerLDR(){

  //Realiza a leitura e entao a mapeia entre 0 e 100

  int leitura_LDR = customARead(PINO_LDR);

  leitura_LDR = map(leitura_LDR, 0, 4095, 100, 0);

​

  //Escreve o valor lido no pino virtual "V0" do aplicativo

  Blynk.virtualWrite(V0, leitura_LDR);

}

​

//---------------------------------------------------------------------------------------

//Funcao do Terminal

BLYNK_WRITE(V1){

​

  terminal.clear(); //Limpa o terminal do aplicativo

  if (String("HIGH") == param.asStr()) { //Verifica se a mensagem enviada no terminal e igual a "HIGH"

    Serial.println("'HIGH' Recebido! Acendendo LED");

    terminal.println("'HIGH' Enviado! Acendendo LED");

    digitalWrite(PINO_LED, HIGH); //Acende o LED

    //Se a mensagem nao for "HIGH"

  } else if(String("LOW") == param.asStr()) { //Verifica se a mensagem enviada no terminal e igual a "LOW"

    Serial.println("'LOW' Recebido! Apagando LED");

    terminal.println("'LOW' Enviado! Apagando LED");

    digitalWrite(PINO_LED, LOW); //Apaga o LED

  } else { //Caso contrario

    terminal.print("Mensagem Enviada: ");

    terminal.println(param.asStr());

    Serial.print("Mensagem Recebida: ");

    Serial.println(param.asStr());

  }

  terminal.flush(); //Garante o envio da mensagem

}

​

//---------------------------------------------------------------------------------------

//Funcao para ler o DHT e enviar as leituras para o Blynk

void lerDHT(){

​

  //Declaracao das variaveis que armazenam as leituras do sensor

  float temperatura;

  float umidade;

​

  //Realiza a leitura de temperatura e umidade do sensor

  temperatura = dht.readTemperature();

  umidade = dht.readHumidity();

​

  //Verifica se a leitura foi feita corretamente

  if (isnan(umidade) || isnan(temperatura)) {

    Serial.println("Falha na leitura do Sensor DHT!");

  } else {

    //Escreve os valores lidos nos pinos virtuais do aplicativo

    Blynk.virtualWrite(V2, temperatura);

    Blynk.virtualWrite(V3, umidade);

  }

}

​

//---------------------------------------------------------------------------------------

//Funcao para ler o acelerometro e enviar as leituras para o Blynk

void lerAcelerometro(){

​

  //Realiza a leitura do acelerometro

  acelerometro.read();

​

  //Escreve os valores lidos nos pinos virtuais do aplicativo

  Blynk.virtualWrite(V4, acelerometro.x);

  Blynk.virtualWrite(V5, acelerometro.y);

  Blynk.virtualWrite(V6, acelerometro.z);

}

​

//---------------------------------------------------------------------------------------

void setup(){

  //Inicializacao do monitor serial

  Serial.begin(115200);

  Serial.println("Waiting for connections...");

​

  //Define "PINO_LDR" como uma entrada

  pinMode(PINO_LDR, INPUT);

  adc_register = READ_PERI_REG(SENS_SAR_READ_CTRL2_REG); //Estado atual do registrador

​

  //Definicao do pino do LED como uma saida do sistema

  pinMode(PINO_LED, OUTPUT);

​

  //Inicializacao do Blynk com a chave de autenticacao

  Blynk.begin(CHAVE_AUTENTICACAO);

​

  //Inicializacao do sensor DHT

  dht.begin();

​

  //Inicializacao do acelerometro

  acelerometro.init();

​

  //Configura o timer do LDR com intervalo de 1 segundo

  timerLDR.setInterval(1000L, lerLDR);

  //Configura o timer do DHT com intervalo de 10 segundos

  timerDHT.setInterval(10000L, lerDHT);

  //Configura o timer do acelerometro com intervalo de 100 milissegundos

  timerACELEROMETRO.setInterval(100L, lerAcelerometro);

}

​

//---------------------------------------------------------------------------------------

void loop(){

  Blynk.run(); //Mantem a conexao ativa com o aplicativo e processa comandos recebidos ou enviados

  timerLDR.run(); //Execucao do timer do LDR

  timerDHT.run(); //Execucao do timer do DHT

  timerACELEROMETRO.run(); //Execucao do timer do acelerometro

}

​

//---------------------------------------------------------------------------------------

//Funcao responsavel por ler o ADC conectado ao LDR

int customARead(int pin){

  uint32_t wifi_register = READ_PERI_REG(SENS_SAR_READ_CTRL2_REG);

  WRITE_PERI_REG(SENS_SAR_READ_CTRL2_REG, adc_register);

  SET_PERI_REG_MASK(SENS_SAR_READ_CTRL2_REG, SENS_SAR2_DATA_INV);

  int value = analogRead(pin); //Realiza a leitura

  WRITE_PERI_REG(SENS_SAR_READ_CTRL2_REG, wifi_register);

  return value; //Retorna o valor lido

}