Irrigador Automático com Arduino

Introdução

Este projeto é basicamente uma continuação do nosso tutorial sobre o sensor de umidade de solo capacitivo, onde aprendemos a coletar as leituras e a calibrá-lo corretamente, porém só criamos um alerta para nos avisar quando é necessário irrigar o solo.

Neste projeto iremos usar a bomba peristáltica para irrigar o solo automaticamente quando o solo estiver seco, e interromper a irrigação quando o solo alcançar uma determinada concentração de água.

Lista de Materiais

Lista completa de produtos

comprar

BlackBoard UNO R3

R$ 94,90 no PIX

Bomba Peristáltica 12V

R$ 65,55 no PIX

Sensor de Umidade de Solo Capacitivo

R$ 7,12 no PIX

Módulo Relé 5V - Relé Metaltex

R$ 9,97 no PIX

Mangueira de Silicone - 1 metro

R$ 6,17 no PIX

Fonte Chaveada 12V 5A

R$ 34,10 no PIX

Diodo 1N4007 - Pacote com 10 unidades

R$ 1,80 no PIX

Protoboard 400 Pontos

R$ 6,55 no PIX

WorkPlate 400 - Preta

R$ 14,15 no PIX

Jumpers Macho-Macho x40 Unidades

R$ 7,50 no PIX

Jumpers Macho-Fêmea x40 Unidades

R$ 7,50 no PIX

Circuito

Antes de mais nada, monte a WorkPlate 400 do Kit seguindo o manual de montagem contido no botão abaixo.

Manual de Montagem da WorkPlate 400

A bomba peristáltica do Kit não possui um local de fixação específico, portanto você pode fixá-la onde e da maneira que achar melhor. Assim que a WorkPlate 400 estiver completamente montada com a BlackBoard UNO e com a protoboard, monte o circuito a seguir.

Para conectar o motor ao relé e à placa, é recomendado soldar o diodo e um par de jumpers macho-macho aos terminais do motor. Entretanto, como a solda pode ser uma opção complicada em alguns casos, é possível apenas conectar o diodo e os conectores dos jumpers aos terminais do motor, desde que essas conexões sejam garantidas. Além disso, atente-se à polaridade do diodo no circuito.

Código

Com o circuito montado, carregue o código a seguir para a sua placa.

/*******************************************************************************
* Projeto Irrigador Automatico de Solo (v1.0)
* 
* Este codigo monitora a umidade do solo, convertendo a leitura do sensor para 
* um valor entre 0 e 100 %, que aciona a bomba peristática para irrigar o solo,
* quando a leitura estiver abaixo de um valor  minimo determinado, e so interrompe 
* a irrigacao quando a leitura chegar a um valor maximo determinado.
* 
* Copyright <2020> RoboCore.
* Escrito por Giovanni de Castro (16/10/2020).
* 
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version (<https://www.gnu.org/licenses/>).
*******************************************************************************/

//Declaracao do pino conectado ao sensor
const int PINO_SENSOR = A0;

//Declaracao do pino conectado ao rele
const int PINO_RELE = 2;

//Declaracao da variavel que armazena as leituras do sensor
int leitura_sensor = 0;

//Declaracao da variavel auxiliar para o "delay" de 10 segundos
bool pausa = true;

//Declaracao das variaveis que armazenam os valores de calibracao
const int VALOR_MAXIMO = 900; //Valor com solo seco
const int VALOR_MINIMO = 700; //Valor com solo umido
//Altere o valor das variaveis acima de acordo com as medias obtidas atraves do codigo do projeto anterior

//Declaracao das variaveis que armazenam a concentracao maxima e minima desejada
const int CONCENTRACAO_MINIMA = 30;
const int CONCENTRACAO_MAXIMA = 50;
//Altere as variaveis acima com os valores ideais para a sua planta

void setup() {

  //Define o pino conectado ao sensor como uma entrada do sistema
  pinMode(PINO_SENSOR, INPUT);
  
  //Define o pino conectado ao rele como uma saida do sistema
  pinMode(PINO_RELE, OUTPUT);

  //Inicia o pino conectado ao rele com nivel logico baixo
  digitalWrite(PINO_RELE, LOW);
  
}

void loop() {

  //Realiza a leitura do sensor, a mapeia entre 0 e 100 % e exibe o valor no LCD
  leitura_sensor = analogRead(PINO_SENSOR);
  leitura_sensor = map(leitura_sensor, VALOR_MINIMO, VALOR_MAXIMO, 100, 0);

  //Verifica se a leitura esta abaixo da concetracao minima desejada
  if(leitura_sensor < CONCENTRACAO_MINIMA){ //Se sim
    digitalWrite(PINO_RELE, HIGH); //Acionamos o rele
    pausa = false; //Configura a variavel "pausa" como falsa
  } else if (leitura_sensor > CONCENTRACAO_MAXIMA) { //Caso contrario
    digitalWrite(PINO_RELE, LOW); //O rele se mantem desligado
    pausa = true; //Configura a variavel "pausa" como verdadeira
  }

  //Verifica se a variavel "pausa" e verdadeira
  if(pausa){ //Se sim
    delay(10000); //Aguarda 10 segundos para nova leitura
  } 

}

Entendendo o Código

O código inicia com a declaração das variáveis PINO_SENSOR e PINO_RELE, que armazenam os pinos conectados ao sensor e ao relé, respectivamente. Em seguida, declaramos a variável que armazenará a leitura do sensor que será convertida, juntamente com as constantes dos valores máximo e mínimo para a calibração do sensor, e a variável auxiliar pausa, que controlará a execução ou não de uma pausa de 10 segundos entre repetições. Para finalizar as declarações globais do código, temos a declaração das constantes com as concentrações máxima e mínima de água no solo desejadas.

//Declaracao do pino conectado ao sensor
const int PINO_SENSOR = A0;

//Declaracao do pino conectado ao rele
const int PINO_RELE = 2;

//Declaracao da variavel que armazena as leituras do sensor
int leitura_sensor = 0;

//Declaracao da variavel auxiliar para o "delay" de 10 segundos
bool pausa = true;

//Declaracao das variaveis que armazenam os valores de calibracao
const int VALOR_MAXIMO = 632; //Valor com solo seco
const int VALOR_MINIMO = 314; //Valor com solo umido
//Altere o valor das variaveis acima de acordo com as medias obtidas atraves do codigo do projeto anterior

//Declaracao das variaveis que armazenam a concentracao maxima e minima desejada
const int CONCENTRACAO_MINIMA = 30;
const int CONCENTRACAO_MAXIMA = 50;
//Altere as variaveis acima com os valores ideais para a sua planta

Na rotina de configuração do código, configuramos os pinos conectados ao sensor e ao relé como uma entrada e uma saída do sistema, respectivamente. Feito isso, iniciamos o pino conectado ao relé com nível lógico baixo ("LOW").

//Define o pino conectado ao sensor como uma entrada do sistema
pinMode(PINO_SENSOR, INPUT);
  
//Define o pino conectado ao rele como uma saida do sistema
pinMode(PINO_RELE, OUTPUT);

//Inicia o pino conectado ao rele com nivel logico baixo
digitalWrite(PINO_RELE, LOW);

Já na repetição do código, atribuímos à variável leitura_sensor a leitura analógica do pino conectado ao sensor, e então convertemos essa leitura para um valor entre 0 e 100 % de acordo com as variáveis VALOR_MINIMO e VALOR_MAXIMO, usando o comando leitura_sensor = map(leitura_sensor, VALOR_MINIMO, VALOR_MAXIMO, 100, 0). Feito isso, nós verificamos através da condição if(leitura_sensor < CONCENTRACAO_MINIMA) se o valor atribuído à variável leitura_sensor é menor que o valor configurado anteriormente na variável CONCENTRACAO_MINIMA. Se essa condição for verdadeira, acionamos o relé e configuramos a variável pausa como falsa ("false"). Senão, nós verificamos se o valor atribuído à variável leitura_sensor é maior que o valor configurado anteriormente na variável CONCENTRACAO_MAXIMA, através da condição else if (leitura_sensor > CONCENTRACAO_MAXIMA). Se essa condição for verdadeira, nós desligamos o relé e configuramos a variável pausa como verdadeira ("true"). Por fim, verificamos se a variável pausa é verdadeira, e, se for, realizamos uma interrupção na execução de código de 10 segundos. A variável pausa é usada para que a interrupção de 10 segundos do código só ocorra caso o solo tenha alcançado a sua umidade máxima desejada. Enquanto a bomba estiver irrigando o solo, o sistema ficará constantemente medindo a umidade para não encharcá-lo. Porém, depois de irrigado, o solo demora bastante para secar novamente, por isso podemos usar uma pausa entre cada leitura.

//Realiza a leitura do sensor, a mapeia entre 0 e 100 % e exibe o valor no LCD
leitura_sensor = analogRead(PINO_SENSOR);
leitura_sensor = map(leitura_sensor, VALOR_MINIMO, VALOR_MAXIMO, 100, 0);

//Verifica se a leitura esta abaixo da concetracao minima desejada
if(leitura_sensor < CONCENTRACAO_MINIMA){ //Se sim
  digitalWrite(PINO_RELE, HIGH); //Acionamos o rele
  pausa = false; //Configura a variavel "pausa" como falsa
} else if (leitura_sensor > CONCENTRACAO_MAXIMA) { //Caso contrario
  digitalWrite(PINO_RELE, LOW); //O rele se mantem desligado
  pausa = true; //Configura a variavel "pausa" como verdadeira
}

//Verifica se a variavel "pausa" e verdadeira
if(pausa){ //Se sim
  delay(10000); //Aguarda 10 segundos para nova leitura
}

O Que Deve Acontecer

Assim que carregar o código para a placa, insira o sensor no solo que será controlado e alimente a placa com a fonte de 12 V e 5 A. Assim, o sistema irá acionar a bomba peristáltica para irrigar o solo quando ele estiver seco, como no GIF a seguir. Para demonstrar o funcionamento do sistema, utilizamos um copo com água com o sensor, porém, no solo, o sistema deve demorar bem mais para acionar a bomba peristáltica.

Resultado Final

Conclusão

Neste tutorial aprendemos como criar um projeto de irrigador automático, usando as leituras calibradas do sensor de umidade de solo capacitivo para acionar uma bomba peristáltica através de um relé.

Comentários

Para fazer comentários é necessário estar logado. Efetuar login.

Você ainda nao é cadastrado? Cadastre-se agora!

luiz.mendesbarbosa
date

Enviado 2024-11-08 08:35:30

Bom dia! eu comprei a Mini Bomba de Água 12V RS-385 e to com duvida em relação a bateria. Eu não vou ligar na tomada mas sim em uma bateria. To usando uma de 9v para o arduino e queria saber qual usar para a bomba ?

luiz.mendesbarbosa
date

Enviado 2024-11-08 08:36:00
luiz.mendesbarbosa

E tbm qual corrente da bateria suar ?

luan.ferreira
date

Enviado 2024-11-08 08:57:57
luiz.mendesbarbosa

Olá! No caso, pode ser usado uma bateria 12V e com pelo menos 2A. Para mais informações, temos as informações técnicas da bomba: https://www.robocore.net/atuador/mini-bomba-de-agua-12v-rs-385

luiz.mendesbarbosa
date

Enviado 2024-11-08 11:02:30
luiz.mendesbarbosa

Obrigado! Fiquei com medo de por uma de 12 e acabar sobrecarregando o rele ja que ele é conectado a bomba

luan.ferreira
date

Enviado 2024-11-08 13:13:15
luiz.mendesbarbosa

Disponha! Em caso de dúvida ou problema, entre em contato.

williampotter23
date

Enviado 2024-08-05 18:35:49

Boa noite estou para fazer este tutorial,  para 6 sensores capacitivos, uma placa Arduíno UNO. quero colocar o relé serial, como faria a integração com as mini bombas? a saída do relé serial (vendido aqui no site) é 5V, pode conectar direto na bomba de 3V ou precisaria fazer alguma modificação?

carlos.oliveira
date

Enviado 2024-08-06 07:45:42
williampotter23

Olá! Este tutorial e o tutorial "Módulo Relé Serial - Primeiro Contato" ( https://www.robocore.net/tutoriais/primeiros-passos-modulo-rele-serial ) podem ser usados como referência para o desenvolvimento do seu projeto. Em relação às tensões, como você usará o módulo relé serial, recomendamos que use uma alimentação externa para as bombas, uma vez que elas operam em 3 V, enquanto o Arduino opera com tensões diferentes.

carlos.oliveira
date

Enviado 2024-08-06 07:47:02
williampotter23

A fonte externa é recomendada, pois as placas Arduino podem não fornecer corrente suficiente para as bombas. Além disso, os acionamentos das bombas podem causar ruídos na alimentação, logo isso deve ser levado em consideração para que o conjunto funcione adequadamente.

ricardochemistry
date

Enviado 2024-06-13 18:04:45

Hola, não consigo fazer funcionar. Eu adicionei o codigo sugerido abaixo para checar as leituras da humidade e aparecem valores aleatorios, de 0 a 1023. No projeto anterior a humidade era medida corretamente.

carlos.oliveira
date

Enviado 2024-06-14 07:57:01
ricardochemistry

Olá! Para que possamos compreender melhor o problema relatado e lhe auxiliar da melhor forma, peço que envie um e-mail para suporte@robocore.net juntamente com um vídeo demonstrando o problema e uma foto do circuito.

adolfosp
date

Enviado 2024-03-17 16:38:27

Existe alguma forma de eu aumentar o cabo do sensor de umidade? Vou implementar isso em um palete de madeira e a distância entre as plantas é grande para o sensor alcançar

Giovanni5

Enviado 2024-03-18 07:13:35
adolfosp

Sim, você pode utilizar jumpers macho-macho (https://www.robocore.net/cabo/jumpers-macho-macho-x40-unidades) ou macho-fêmea (https://www.robocore.net/cabo/jumpers-macho-macho-x40-unidades) para estender o cabo do sensor o quanto desejar.

rocamargo08
date

Enviado 2023-11-07 15:12:20

Vocês tem algum projeto para irrigação de jardim?

luan.ferreira
date

Enviado 2023-11-07 16:24:02
rocamargo08

Olá! Infelizmente não temos nenhum projeto voltado para essa aplicação.

ivan.lins
date

Enviado 2023-10-23 02:51:32

Olá, gostaria de um desse mais completo, para 4 ou 5 vasos, e consigo colocar em uma tomada inteligente pra usar no app ?
se tiver como montar um kit assim, vou querer um!
Obrigado desde já.

luan.ferreira
date

Enviado 2023-10-23 08:06:39
ivan.lins

Olá! Agradecemos a sua sugestão! Neste caso, você pode replicar a lógica usada neste tutorial para adicionar mais sensores. Vale dizer que a placa pode ser alimentada com uma fonte de alimentação externa (de 7 a 12V DC).

ivan.lins

Enviado 2023-10-23 09:37:08
ivan.lins

Obrigado, quanto essa base igual no exemplo acima, eu consigo onde? e é possível colocar em algum app ?

luan.ferreira
date

Enviado 2023-10-23 13:26:50
ivan.lins

A base usada no exemplo infelizmente não está disponível para venda, pois ela foi criada apenas para uso interno. Sobre o aplicativo, é possível realizar adaptações no projeto, para que seja possível acompanhar/controlar o funcionamento através de um aplicativo. No entanto, dependendo de como isso será feito, será necessário adquirir mais itens, e infelizmente não temos um tutorial que mostra a como realizar essa adaptação.  : )

gobimartinelli
date

Enviado 2023-08-29 09:48:28

Prezados, bom dia!

Fiquei com uma dúvida, é preciso uma fonte de 12v só para a bomba peristáltica ou o Arduino da conta de alimentá-la?

luan.ferreira
date

Enviado 2023-08-29 09:59:06
gobimartinelli

Olá! Neste projeto, a fonte de 12V 5A, é usada para alimentar a placa e a bomba. Isso é possível, pois usamos o pino VIN da placa para alimentar a bomba, pois este pino está ligado diretamente à alimentação da placa via conector P4.

itambe.lima
date

Enviado 2023-08-19 14:54:22

Boa tarde, surgiu uma dúvida quanto a instalação da mini bomba, se por acaso faltar água, a boma continuará ligada, pode a queimar?

luan.ferreira
date

Enviado 2023-08-21 10:59:34
itambe.lima

Olá! Não é recomendado usar a bomba sem ela estar bombeando um líquido. No entanto, a falta de líquido não deve danificar a bomba a curto prazo, isto é, manter a acionada mas sem líquido por muito tempo, pode acabar a danificando, uma vez que o líquido ajuda a manter o plástico da bomba estável.

itambe.lima
date

Enviado 2023-05-14 17:37:17

Boa noite, na imagem do projeto o motor está ligado na placa com o auxílio do Relé direto, porem se no lugar da boma eu ligar uma válvula de solenoide 220v ou 110v, pode ser que a placa não aguenta ligar a solenoide. Como resolver esse gargalo para a válvula poder receba a carga de 220v ou 110v sem forcar o Relé, ou a placa?

luan.ferreira
date

Enviado 2023-05-15 10:32:17
itambe.lima

Neste caso, não há problemas para o relé acionar as cargas (220v ou 110v) desejadas. No entanto, não será possível utilizar a alimentação da placa (como mostrado no circuito), para acionar a carga. Para a sua aplicação, será necessário modificar a fonte de energia que será conectada no borne do relé.

Hans

Enviado 2023-03-26 11:01:27

Bom dia, tenho uma estante com diversos tipos de plantas, onde cada uma delas necessita de uma umidade específica, teria como eu adicionar um potenciometro para regular a umidade para cada planta? Sei que vou precisar de mais sensores, bombas, etc, mas gostaria desta regulagem pois caso troque o tipo de planta eu possa regular a umidade para a nova planta selecionada. Exemplo: tenho 3 plantas, a planta A precisa 60% umidade a B 40% a C 80% ai a esposa resolve trocar a B e esta nova planta precisa 20%, ai entra a questão do potenciometro para fazer a nova regulagem de forma simples e prática.

luan.ferreira
date

Enviado 2023-03-27 09:12:18
Hans

Sim, é possível adaptar o projeto para a sua aplicação. No entanto, será necessário adaptar o código e o circuito, para que ele funcione da maneira desejada.