Primeiros Passos com o Shield LoRaWAN em OTAA

/*******************************************************************************

* Shield LoRaWAN - Envio de Mensagens LoRaWAN por OTAA (v1.0)

* 

* Codigo para enviar um contador incremental a plataforma ProIoT cada vez que o

* botao do Shield for pressionado. O LED L do Shield e da placa base irao piscar

* a cada envio/retorno de mensagem do Shield. Se algum problema for encontrado

* na configuracao do Shield, o LED L ficara permanentemente aceso.

* 

* Copyright 2022 RoboCore.

* Escrito por Giovanni de Castro (02/06/2022).

* Creditos: @francois - RoboCore

* 

* This program is free software: you can redistribute it and/or modify

* it under the terms of the GNU Lesser General Public License as published by

* the Free Software Foundation, either version 3 of the License, or

* (at your option) any later version (<https://www.gnu.org/licenses/>).

*******************************************************************************/

​

// --------------------------------------------------

​

//Adicao das biblitoecas

#include <RoboCore_SMW_SX1262M0.h>

#include <SoftwareSerial.h>

#include <ArduinoJson.h>

​

// --------------------------------------------------

​

//Criacao do objeto para biblitoeca "SoftwareSerial"

SoftwareSerial LoRaSerial(10, 11); //RX, TX

//Criacao do objeto para a biblioteca "SMW_SX1262M0" utilizando o objeto da biblioteca "SoftwareSerial"

SMW_SX1262M0 LoRaWAN(LoRaSerial);

​

//Declaracao da variavel que armazena as respostas do Shield

CommandResponse response;

​

//Declaracao das variaveis que armazenam as informacoes da rede

const char APPEUI[] = "SEU-APPEUI-AQUI"; //Application EUI

const char APPKEY[] = "SEU-APPKEY-AQUI"; //Application Key

//As variaveis acima devem ser alteradas de acordo com os codigos gerados na plataforma ProIoT

​

//Declaracao da variavel que armazena o estado de conexao do Shield

bool conectado = false;

//Declaracao do contador incrementavel que sera usado para o envio de mensagens

int contador = 0;

​

//Declaracao da variavel que armazena o ALIAS da variavel criada na ProIoT

const char ALIAS[] = "Data";

​

//Declaracao da variavel que armazena o pino conectado ao botao do Shield

const int PINO_BOTAO = A0;

​

//Declaracao da variavel que armazena o pino conectadi ao LED L do Shield

const int PINO_LED = 13;

​

// --------------------------------------------------

// --------------------------------------------------

​

//Configuracao do codigo

void setup() {

  //Inicializacao do monitor serial para acompanhar a execucao do codigo

  Serial.begin(9600);

  Serial.println(F("--- Primeiros Passos com o Shield LoRaWAN ---"));

  Serial.println(F("--- Envio de Mensagens por OTAA ---"));

​

  //Configuracao dos pinos usados da placa base

  pinMode(PINO_BOTAO, INPUT_PULLUP); //Botao do Shield

  pinMode(PINO_LED, OUTPUT); //LED L do Shield e da placa base

  digitalWrite(PINO_LED, LOW); //LED L iniciado apagado

​

  //Inicializacao da comunicacao com o Shield

  LoRaSerial.begin(9600);

​

  //Reinicializacao do Shield

  LoRaWAN.reset();

​

  //Configura o Shield para operar no metodo de conexao OTAA

  response = LoRaWAN.set_JoinMode(SMW_SX1262M0_JOIN_MODE_OTAA);

  if (response == CommandResponse::OK) {

    Serial.println(F("Metodo de conexao configurado como OTAA"));

    //Pisca o LED L

    digitalWrite(PINO_LED, HIGH);

    delay(100);

    digitalWrite(PINO_LED, LOW);

  } else {

    Serial.println(F("Erro ao configurar modo de conexao"));

    //Mantem LED L aceso

    digitalWrite(PINO_LED, HIGH);

  }

​

  //Coleta o DevEUI do Shield

  char deveui[16];

  response = LoRaWAN.get_DevEUI(deveui);

  if (response == CommandResponse::OK) {

    Serial.print(F("DevEUI: "));

    Serial.write(deveui, 16);

    Serial.println();

    //Pisca o LED L

    digitalWrite(PINO_LED, HIGH);

    delay(100);

    digitalWrite(PINO_LED, LOW);

  } else {

    Serial.println(F("Erro ao coletar o DevEUI"));

    //Mantem LED L aceso

    digitalWrite(PINO_LED, HIGH);

  }

​

  //Configura o AppEUI do dispositivo criado na ProIoT

  response = LoRaWAN.set_AppEUI(APPEUI);

  if (response == CommandResponse::OK) {

    Serial.print(F("Application EUI configurado ("));

    Serial.write(APPEUI, 16);

    Serial.println(')');

    //Pisca o LED L

    digitalWrite(PINO_LED, HIGH);

    delay(100);

    digitalWrite(PINO_LED, LOW);

  } else {

    Serial.println(F("Erro ao configurar o AppEUI"));

    //Mantem LED L aceso

    digitalWrite(PINO_LED, HIGH);

  }

​

  // Configura o AppKEY do dispositivo criado na ProIoT

  response = LoRaWAN.set_AppKey(APPKEY);

  if (response == CommandResponse::OK) {

    Serial.print(F("Application Key configurado ("));

    Serial.write(APPKEY, 32);

    Serial.println(')');

    //Pisca o LED L

    digitalWrite(PINO_LED, HIGH);

    delay(100);

    digitalWrite(PINO_LED, LOW);

  } else {

    Serial.println(F("Erro ao configurar AppKEY"));

    //Mantem LED L aceso

    digitalWrite(PINO_LED, HIGH);

  }

​

  //Salva as informacoes configuradas na memoria do Shield

  //Este trecho e opcional

  response = LoRaWAN.save();

  if (response == CommandResponse::OK) {

    Serial.println(F("Configuracoes salvas"));

    //Pisca o LED L

    digitalWrite(PINO_LED, HIGH);

    delay(100);

    digitalWrite(PINO_LED, LOW);

  } else {

    Serial.println(F("Erro ao salvar configuracoes"));

    //Mantem LED L aceso

    digitalWrite(PINO_LED, HIGH);

  }

​

  //Envia uma requisicao de conexao a rede ATC

  Serial.println(F("Conectando a rede..."));

  //Pisca o LED L

  digitalWrite(PINO_LED, HIGH);

  delay(100);

  digitalWrite(PINO_LED, LOW);

  LoRaWAN.join();

}

​

// --------------------------------------------------

// --------------------------------------------------

​

//Repeticao do Codigo

void loop() {

​

  //Verifica se o modulo esta conectado na rede

  if (LoRaWAN.isConnected()) {

    //Atualiza a variavel que armazena o estado de conexao do Shield

    if (!conectado) {

      Serial.println(F("Conectado!"));

      conectado = true; // set

    }

​

    //Verifica se o botao do Shield foi pressionado

    if (digitalRead(PINO_BOTAO) == LOW) {

      delay(30); //Debounce

      if (digitalRead(PINO_BOTAO) == LOW) {

​

        //Pisca o LED L

        digitalWrite(PINO_LED, HIGH);

        delay(100);

        digitalWrite(PINO_LED, LOW);

​

        //Incrementa em uma unidade o contador

        contador++;

        if (contador > 255) {

          contador = 0; // reset

        }

​

        //Cria o objeto dinamico "json" com tamanho "1" para a biblioteca

        DynamicJsonDocument json(JSON_OBJECT_SIZE(1));

​

        //Atrela ao objeto "json" ao contador com o valor ja atualizado com o nome do ALIAS definido

        json[ALIAS] = contador;

​

        //Mede o tamanho da mensagem "json" e atrela o valor somado em uma unidade ao objeto "tamanho_mensagem"

        size_t tamanho_mensagem = measureJson(json) + 1;

​

        //Cria a string "mensagem" de acordo com o tamanho do objeto "tamanho_mensagem"

        char mensagem[tamanho_mensagem];

​

        //Copia o objeto "json" para a variavel "mensagem" e com o "tamanho_mensagem"

        serializeJson(json, mensagem, tamanho_mensagem);

​

        //Envia a mensagem

        Serial.print(F("Mensagem: "));

        Serial.println(mensagem);

        response = LoRaWAN.sendT(1, mensagem);

​

      }

    }

​

  //Se ainda nao estiver conectado

  } else if (!conectado) {

    //Demonstra tentativa de conexao

    Serial.println('.');

    //Pisca o LED L

    digitalWrite(PINO_LED, HIGH);

    delay(100);

    digitalWrite(PINO_LED, LOW);

    //A cada 5 segundos

    delay(5000);

  }

​

}

​

// --------------------------------------------------

// --------------------------------------------------