Kit Iniciante Robótica - 8. Robô Seguidor de Linha

O Kit Iniciante para Robótica acompanha um par de Sensores de Refletância QRE Analógicos para detecção da linha. Esses sensores trabalham emitindo um feixe de luz infravermelha (IR) em direção a superfície abaixo do robô e medindo o quanto de luz é refletida. No sensor, você notará que existem dois pequenos retângulos. Um deles é o emissor IR e o outro é o detector.

Os sensores de linha funcionam melhor quando estão perto da superfície abaixo do robô. O sensor deve estar cerca de 3mm acima do solo. Essa é uma ótima distância para que o emissor IR ilumine a superfície e realize a leitura da luz refletida. Mas fique tranquilo, se você seguiu o passo-a-passo de montagem corretamente, os sensores estarão bem posicionados.
Nota: Os olhos humanos não são sensíveis a luz infravermelha, portanto, a menos que você seja um super-herói, você não conseguirá enxergar a luz emitida pelos sensores. Mas se você utilizar uma câmera CCD, como a de seu smartphone, você poderá ver pequenos pontos de luz saindo de seus sensores.

Enxergando a Linha

Nesse exemplo iremos simplesmente ler e imprimir os valores de nossos Sensores de Linha. É interessante que você teste os sensores sobre diversos cenários para possa entender o comportamento deles.
Carregue esse código de exemplo para a placa Julieta. Para isso, vá em: Arquivo->Exemplos->RoboCore Falcon Robot Library->Exp4_1_LineFollowing ou copie e cole o código de exemplo abaixo.

/*******************************************************************************
* Exp4_1_LineFollowing -- FalconRobot Experiment 4.1
*
* This code reads the two line following sensors on A2 and A3
* and prints them out to the Serial Monitor. Upload this example to your
* FalconRobot and open up the Serial Monitor by clicking the magnifying glass
* in the upper-right hand corner.
*
* Hardware setup:
* The Line Sensors must be connected to pins A2 and A3 (left and right sensor,
* respectively).
*
* This sketch was written by RoboCore, with lots of help from the Arduino
* community(especially from Sparkfun). This code is completely free for any use.
*
* Visit https://www.robocore.net/tutoriais/kit-iniciante-robotica-introducao
* for Falcon Robot Kit Information
*
* 20 Jul 2017 MarceloFariaz
*******************************************************************************/

#include "FalconRobot.h"
// initialize a sensor object on A2 and A3
FalconRobotLineSensor lineSensor1 = FalconRobotLineSensor(A2);
FalconRobotLineSensor lineSensor2 = FalconRobotLineSensor(A3);

void setup() {
  Serial.begin(9600); // Setup the Serial to a speed of 9600bps
  Serial.println("Welcome to experiment 5!");
}

void loop() {
  // Print the sensors values
  Serial.print("Line Sensor Readings: ");
  Serial.print(lineSensor1.read());
  Serial.print("\t"); // tab character
  Serial.print(lineSensor2.read());
  Serial.println(); // new line
  delay(100);
}

Após carregar o código para seu robô, abra o Monitor Serial para visualizar a leitura de seus sensores. Você deve observar uma janela assim:

Se você realizou as ligações corretas, na primeira coluna você terá os valores lidas pelo sensor esquerdo e na segunda coluna os valores lidos pelo sensor direito.

Exercício: Entendendo o comportamento dos Sensores

Os sensores infravermelhos operam em um alcance bem curto. Eles são ótimos quando estão entre 3mm e 5mm da superfície. Teste isso com o seu próprio robô. Conforme a figura abaixo, pegue uma folha de papel em branco e cole um pedaço da Fita Isolante que acompanha o Kit.

Com o robô conectado ao seu computador, realize os seguintes testes:

Coloque o seu robô sobre sua mesa. Quais sãos os valores lidos pelos dois sensores?
Posicione-o sobre a folha com fita. Quais os valores lidos sobre a fita? E sobre a superfície branca?
Com o robô ainda sobre a mesa, apague as luzes do ambiente ou cubra ele com um cobertor ou algo do gênero. O que acontece com os valores lidos? O que você acha que está causando isso?
Mova o robô lentamente para a borda da mesa. Observe as leituras enquanto os sensores se aproximam da borda da mesa. Quais são os valores dos sensores quando eles estão fora da mesa?

Agora você pode utilizar esses valores para programar seu robô para fazer coisas como ficar sobre a mesa ou seguir uma linha!

Entendendo o código

Para configurar uma conexão entre o robô e seu computador, é necessário utilizar o Objeto Serial no Arduino. No setup(), o comando Serial.begin(9600); inicializa a Serial do Arduino e determina a velocidade com que os dados são trasmitidos e recebidos entre o robô e o computador. O valor de 9600 define o baud rate, ou seja, o número de bits por segundo. Essa é uma boa velocidade para a maiora das aplicações, mas outras velocidades são suportadas pelo Arduino, como: 300, 1200, 2400, 4800, 9600, 14400, 19200, 28800, 38400, 57600, and 115200.

Serial.begin(9600);

Para enviar dados do robô para seu computador, você pode utilizar basicamente dois comandos: Serial.print(""); e Serial.println("");. O primeiro comando, Serial.print(""); simplesmente imprime o texto entre aspas ("") ou algum dado (em forma de número ou variável) para o barramento Serial - isso é mostrado no Monitor Serial. O segundo comando, Serial.println(""); é o mesmo, mas adiciona um caractere de retorno de carro e de nova linha, movendo o cursor para o início da próxima linha.

Serial.print("Line Sensor Readings: ");
  
Serial.println(); // new line

Imprimindo Caracteres Especiais

Existem alguns caracteres especiais que você pode imprimir. Abaixo você confere alguns que são utilizados em C e C++:

Código	Descrição
\t	Caractere TAB
\"	Aspas Duplas
\'	Aspas Simples
\n	CRLF - nova linha

Biblioteca FalconRobot

O FalconRobotLineSensor é um objeto criado para facilitar a interação com os sensores de linha que acompanham o Kit. No robô, os sensores de linha foram conectados aos pinos A2 e A3 da Julieta. Por esse motivo, nas linhas abaixo foi criado um objeto cuidar da leitura de cada sensor.

  // initialize a sensor object on A2 and A3
  FalconRobotLineSensor lineSensor1 = FalconRobotLineSensor(A2);
  FalconRobotLineSensor lineSensor2 = FalconRobotLineSensor(A3);

A classe FalconRobotLineSensor possui vários métodos, mas para esse projeto em específico o principal é o xxxx.read();. Este método retorna um valor entre 0 e 1023 baseado na tensão de entrada do sensor. Lembre-se que o xxxx representa o nome do ojeto(nesse caso, lineSensor1 ou lineSensor2).

  Serial.print(lineSensor1.read());

Solução de Problemas

Nada está sendo impresso no Monitor Serial!

Verifique se o baud rate foi configurado corretamente em seu monitor serial. Existe um menu no canto inferior direito, ele deve estar configurado para o baud rate de 9600.

O valor do meu sensor não muda!

Verifique se os sensores foram corretamente conectados em sua placa Julieta.
Tente trocar um sensor com outro.

Agora que você já entendeu como funcionam os sensores de reflectância infravermelhos, chegou a hora de aprender como fazer o seu robô "andar na linha"!

Uma curiosidade: você sabia que existem várias competições de robôs seguidores de linha em todas as partes do mundo, inclusive no campeonato mundial de robótica que a RoboCore organiza todos os anos? É isso mesmo, os conceitos base que você aprenderá aqui poderão ser utilizados para quem sabe construir um robô de competição!

Seguindo a Linha

O algoritmo para manter o robô sobre o percurso é bastante simples. Note que o objetivo principal é manter sempre os dois sensores sobre a linha, pois dessa maneira o robô estará centralizado no caminho que deve percorrer. Portanto, a lógica básica que deve ser implementada é:

Se os dois sensores estejam sobre a linha, ande para frente(motor esquerdo e direito com a mesma velocidade).
Se o sensor esquerdo estiver sobre a linha e o sensor direito estiver fora da linha, vire para esquerda(motor esquerdo um pouco mais lento e o motor direito um pouco mais rápido).
Se o sensor direito estiver sobre a linha e o sensor esquerdo estiver fora da linha, vire para direita(motor direito um pouco mais lento e o motor esquerdo um pouco mais rápido).

Note que também existe uma quarta hipótese onde os dois sensores estão fora da linha (4), porém neste tutorial serão consideradas apenas as três primeiras situações, deixando a seu critério escolher o que fazer quando esse último caso ocorrer.

Carregue esse código de exemplo para a sua Plataforma Falcon. Para isso, vá em: Arquivo->Exemplos->RoboCore Falcon Robot Library->Exp4_2_LineFollowing ou copie e cole o código de exemplo abaixo.

/*******************************************************************************
* Exp4_2_LineFollowing -- Falcon Robot Experiment 4.2
*
* This code reads the two line following sensors on A2 and A3
* and prints them out to the Serial Monitor. Upload this example to your
* Falcon Robot and open up the Serial Monitor by clicking the magnifying glass
* in the upper-right hand corner.
*
* This is a real simple example of a line following algorithm. It has
* a lot of room for improvement, but works fairly well for a curved track.
* It does not handle right angles reliably -- maybe you can come up with a
* better solution?
*
* Hardware setup:
* The Line Sensors must be connected to pins A2 and A3 (left and right sensor,
* respectively). The motors must be connected, and the board must be receiving
* power from the battery pack.
*
* This sketch was written by RoboCore, with lots of help from the Arduino
* community(especially from Sparkfun). This code is completely free for any use.
*
* Visit https://www.robocore.net/tutoriais/kit-iniciante-robotica-introducao
* for Falcon Robot Kit Information
*
* 20 Jul 2017 MarceloFariaz
*******************************************************************************/

#include "FalconRobot.h"
// initialize a sensor object on A2 and A3
FalconRobotLineSensor left(A2);
FalconRobotLineSensor right(A3);

int leftValue;  // variable to store the left sensor value
int rightValue;  // variable to store the right sensor value

// constants that are used in the code. LINETHRESHOLD is the level to detect
// if the sensor is on the line or not. If the sensor value is greater than this
// the sensor is above a DARK line.
//
// SPEED sets the nominal speed

#define LINETHRESHOLD 700
#define SPEED 50  // Set to any number from 0 - 100.

FalconRobotMotors motors(5, 7, 6, 8);
int leftSpeed;   // variable used to store the leftMotor speed
int rightSpeed;  // variable used to store the rightMotor speed


void setup() {
  Serial.begin(9600);
  Serial.println("Welcome to experiment 5.2 - Line Following");
  delay(2000);
  Serial.println("Line Sensor Readings: ");
  delay(500);
}

void loop() {

  // Read the sensors
  leftValue = left.read();
  rightValue = right.read();

  // Print the sensors values
  Serial.print(leftValue);
  Serial.print("\t");  // tab character
  Serial.print(rightValue);
  Serial.println();   // new line

  // if the both sensors are on the line, drive forward left and right at the same speed
  if((leftValue > LINETHRESHOLD) && (rightValue > LINETHRESHOLD)) {
  	leftSpeed = SPEED;
  	rightSpeed = SPEED;
  }

  // if the line only is under the right sensor, adjust relative speeds to turn to the right
  else if(rightValue > LINETHRESHOLD) {
  	leftSpeed = SPEED + 40;
  	rightSpeed = SPEED - 40;
  }

  // if the line only is under the left sensor, adjust relative speeds to turn to the left
  else if(leftValue > LINETHRESHOLD) {
  	leftSpeed = SPEED - 40;
  	rightSpeed = SPEED + 40;
  }

  // run motors given the control speeds above
  motors.leftDrive(leftSpeed, FORWARD);
  motors.rightDrive(rightSpeed, FORWARD);

  delay(0);  // add a delay to decrease sensitivity.
}

Após carregar o código para seu robô, posicione-o sobre a folha branca com fita que você fez no último capítulo. Tente replicar as hipóteses citadas acima e verifique se o robô responde conforme a lógica necessária para seguir a linha. Ou seja, coloque o robô com os dois sensores em cima da linha e veja se os dois motores giram no mesmo sentido, fazendo o robô ir para frente. Faça o mesmo para os casos em que apenas um sensor está sobre a linha e veja se o robô vira para o lado correto.

Exercício: Construindo uma pista

A parte mais legal em construir um robô que segue linha é oberservá-lo percorrendo um percurso sozinho. Portanto nada mais justo que você construa um pequeno circuito para seu robô.

Para isso, basta aplicar a fita isolante que você recebeu junto do Kit sobre uma superfície clara e grande o suficiente para o seu circuito. Lembre-se que é importante que exista uma boa diferença de reflectância entre a fita preta e a superfície onde a pista é construída para que o robô consiga identificar a linha.
É importante que a superfície seja clara, plana e sem grandes ondulações ou vãos. Você pode construir sobre uma mesa, sobre cartolinas ou até em um chão que não tenha grandes depressões. Fique atento também para o espaçamentos entre as linhas, pois se dois trechos da pista estiverem muito perto, as chances de o robô se perder aumentam consideravelmente.

Atenção: se você construir sua pista em uma superfície elevada, como uma mesa, fique muito atento sempre que colocar o robô para seguir, pois eventualmente ele poderá sair do percurso e até mesmo cair da mesa.

A imagem acima mostra um bom exemplo de pista para se construir. É um modelo simples e que provavelmente seu robô não terá problemas em seguir o percurso.

Entendendo o código

Nesse exemplo foram utilizadas duas constantes. A constante LINETHRESHOLD e a constante SPEED. A primeira, LINETHRESHOLD, define qual o limite entre a linha escura e a superfície da pista. Ou seja, se o valor de sensor estiver abaixo do limite, então o sensor está sobre a superfície branca, caso ele esteja acima do limite, então o sensor está sobre a linha. Já a segunda, SPEED, define a velocidade nominal dos motores quando ele deve seguir em frente.
Note que nesse código foi utilizado a expressão #define. Essa palavra permite a criação de constantes sem ocupar a memória de variáveis do seu Arduino.

  #define LINETHRESHOLD 700
  #define SPEED 50  // Set to any number from 0 - 100.

A parte do código onde a lógica propriamente dita é implementada está nas linhas abaixo. Você pode observar 3 condicionais. Cada uma delas trata dos casos citados no início desse capítulo. O primeiro if cuida da ocasião onde os dois sensores estão sobre a linha, definindo as velocidades dos motores para a velocidade nominal, fazendo com que robô siga em linha reta.
Já o segundo condicional, else if cuida do caso onde apenas o sensor direito está sobre a linha e o robô deve virar à direita. Nesse caso, a velocidade do motor da direita é reduzida e a do motor da esquerda aumentada.
No último if do programa cuida do ultimo caso, onde o robô deve virar para esquerda.

  // if the both sensors are on the line, drive forward left and right at the same speed
  if((leftValue > LINETHRESHOLD) && (rightValue > LINETHRESHOLD)) {
  	leftSpeed = SPEED;
  	rightSpeed = SPEED;
  }

  // if line is only under the right sensor, adjust relative speeds to turn to the right
  else if(rightValue > LINETHRESHOLD) {
  	leftSpeed = SPEED + 40;
  	rightSpeed = SPEED - 40;
  }

  // if line is only under the left sensor, adjust relative speeds to turn to the left
  else if(leftValue > LINETHRESHOLD) {
  	leftSpeed = SPEED - 40;
  	rightSpeed = SPEED + 40;
  }

Vale aqui uma explicação sobre a rotina if e else if, ambas utilizadas no código. A palavra IF em inglês significa SE, em português, enquanto que ELSE IF significa SE NÃO, SE... Ou seja, utilizamos as rotinas para expressas o que queremos que seja feito caso uma condição seja atendida, e o que queremos que aconteça caso essa mesma condição não seja atendida. Isso fica mais fácil de entender se colocarmos da forma que pensamos. Vejamos:

  SE (valor do sensor da esquerda for MAIOR que constante LINETHRESHOLD) E TAMBÉM SE (valor do sensor da direita for MAIOR que constante LINETHRESHOLD) faça:
    Velocidade da esquerda será igual a constante SPEED e
    Velocidade da direita será igual a constante SPEED.
  
  SE NÃO, SE (valor do sensor da direita for MAIOR que constante LINETHRESHOLD), faça: 
    Velocidade da esquerda será igual a constante SPEED acrescida de 40 e
    Velocidade da direita será igual a constante SPEED descrescida de 40.
  
  SE NÃO, SE (valor do sensor da esquerda for MAIOR que constante LINETHRESHOLD), faça: 
    Velocidade da esquerda será igual a constante SPEED descrescida de 40 e
    Velocidade da direita será igual a constante SPEED acrescida de 40.

Note que o símbolo && significa que as duas condicionais tem que ser atendidas para uma ação ser executada.

Indo Além

Indo mais rápido

Esse código realmente só funciona quando o robô está se movendo devagar e as vezes ele sairá da linha em curvas acentuadas. O que você pode fazer para que funcione melhor?
Dica: existe uma técnica de controle muito popular chamada PID que é muito utilizadas para as mais diversas aplicações onde se precisa estabilizar um sistema com entradas e saídas, como um robô seguidor de linha, por exemplo. Para saber mais, clique aqui.

Outros experimentos relacionados

Com os conceitos aprendidos nesse capítulo você desenvolver outros experimentos legais. Por exemplo, você seria capaz de modificar o código de tal maneira que, ao colocar o robô dentro de um quadrado, círculo ou qualquer outra forma geométrica fechada, ele se mantenha dentro do espaço delimitado?

Solução de Problemas

O robô vibra muito na hora de seguir!

Ajustando os valores de velocidade nominal, o valor limite da linha e os valores que são incrementados e decrementados na hora de virar, você conseguirá fazer com que o robô siga mais suavemente o percurso.

O robô não segue a linha

Verifique as conexões dos sensores e dos motores, pois é possível que alguma ligação esteja invertida e o circuito não corresponda com a lógica implementada no código.

Comentários

Para fazer comentários é necessário estar logado. Efetuar login.

Você ainda nao é cadastrado? Cadastre-se agora!

prof.rodrigoluiz
date

Enviado 2021-10-05 08:44:32

Uma sugestão para quem está explorando este tutorial:

O código acima é capaz de corrigir o traçado quando um dos sensores está sobre a linha e outro fora dela. Porém, caso os dois sensores saiam da linha, o robô não sabe de que lado da linha ele está. Eu contornei esse problema seguindo as bordas da linha ao invés de seguir a linha em si. Usando esse método, é possível usar uma variável para identificar cada borda e, caso se perca, o robô consegue corrigir o curso de uma forma mais eficaz já que ele sabe se está a direta ou a esquerda da linha. Ainda assim, ele oscila bastante.

Francois

Enviado 2021-10-05 12:18:40
prof.rodrigoluiz

Essa é uma alternativa de controle interessante. Como você deve ter percebido, a fluidez do movimento do robô é uma tarefa um tanto complexa que depende, entre outros, das posições dos sensores e da malha de controle utilizada. Porém, é um ótimo desafio para otimizar o robô seguidor de linha.

prof.rodrigoluiz
date

Enviado 2021-10-04 09:50:58

Muitos exemplos de PID que vi dependem ou de um encoder ou de mais sensores IR. Vocês sabem se é possível implementar um controlador PID usando somente os componentes do kit?

Francois

Enviado 2021-10-04 12:40:04
prof.rodrigoluiz

Muitos projetos usam encoders nos motores e vários sensores infravermelhos para terem mais informações sobre o que está acontecendo com o robô. Porém, você pode implementar um controle PID mais simples usando apenas os dois sensores IR do kit.

prof.rodrigoluiz
date

Enviado 2021-10-04 13:34:40
prof.rodrigoluiz

Obrigado, Francois Vou tentar fazer adaptar um exemplo que encontrei. Vamos ver se dá certo.

prof.rodrigoluiz
date

Enviado 2021-10-05 08:27:13
prof.rodrigoluiz

Voltei a tentar a implementação com PID. Acho até que o meu código está funcionando. Embora eu não tenha trabalhando muito na calibração das constantes.

No meu código eu programei duas funções PID - cada uma dedicada a reduzir a diferença entre a variável LINETHRESHOLD como definida no tutorial de vocês e a leitura do sensor. As correções são obviamente usadas para aumentar ou diminuir a velocidade das rodas conforme necessário. Minha dúvida: eu realmente preciso ter uma função PID para cada sensor ou é possível controlar tudo com uma função só?

Francois

Enviado 2021-10-05 12:14:28
prof.rodrigoluiz

Como o controle PID precisa de um ponto de referência e calcula-se o erro em cima disso, você pode tentar criar um algoritmo que combine os sensores para detectar onde o robô está e atuar os dois motores em função disso. Mas uma forma simples de fazer um controle PID é criando uma malha para cada lado, como você fez.

prof.rodrigoluiz
date

Enviado 2021-10-07 09:47:56
prof.rodrigoluiz

Consegui fazer o controlador PID funcionar. Agora preciso aprender a calibrar as constantes que envolvem o cálculo da correção.

Vou deixar um link para a minha postagem no fórum aqui caso alguém queira se aventurar e me ajudar a fazer a calibração.

https://www.robocore.net/modules.php?name=Forums&file=viewtopic&t=7130

Francois

Enviado 2021-10-07 12:29:36
prof.rodrigoluiz

Muito legal, o seu post pode ajudar várias outras pessoas com seus projetos de PID.

flaviaresende98
date

Enviado 2020-10-25 17:49:53

Nao consigo fazer o robo seguir a linha. Utilizo o código, ele lê os sensores, mas quando coloco pra seguir a linha ele so fica girando em circulos e nao segue o código.

Giovanni5

Enviado 2020-10-26 09:53:19
flaviaresende98

Como os sensores são ópticos e devem ser muito afetados pela iluminação ambiente, é possível que você tenha que calibrar o código com os valores obtidos nas leituras simples dos sensores (primeiro código deste projeto). Além disso, vale a pena conferir a montagem eletrônica dos sensores, pois se eles estiverem conectados incorretamente, eles não funcionarão.

carlos.ed.b
date

Enviado 2020-09-21 17:41:18

boa tarde
estou fazendo os teste e mesmo o motor com velocidade de 20~30 fica um apito e a roda não gira.
não está encostando na carcaça, dou um leve toque a a roda gira.
uma das rodas está com um barulho extremamente alta em relação a outra, na mesma velocidade.

o kit é novo, e desde que abri ele pra testar está assim.
as pilhas são novas, as que vieram no kit.

obrigado

Giovanni5

Enviado 2020-09-22 08:21:51
carlos.ed.b

Você conseguiu realizar o projeto "6. Primeiros Movimentos" (https://www.robocore.net/tutoriais/kit-iniciante-robotica-primeiros-movimentos) corretamente? É possível que a velocidade desta faixa seja pequena demais para que o motor possa partir, portanto tente aumentar um pouco esse parâmetro (velocidade de 40 - 50, por exemplo), e observe o resultado.

carlos.ed.b
date

Enviado 2020-09-22 10:18:07
carlos.ed.b

sim, aumentei e melhorou um pouco, mas está estranho ainda, principalmente a diferença de barulho de uma roda para a outra, ate deixei sem as rodas pra ver, a diferença permanece. 

e aumentando a velocidade, o robô agora sai &#39;de lado&#39;, o que poderia ser?

Giovanni5

Enviado 2020-09-22 10:59:48
carlos.ed.b

Encaminhe por gentileza um e-mail para suporte@robocore.net, com o número do seu pedido, e um vídeo demonstrando esse comportamento.

carlos.ed.b
date

Enviado 2020-09-22 11:05:59
carlos.ed.b

ta bem
Obrigado

felipesoares92
date

Enviado 2019-11-10 19:24:20

Como eu faço caso eu queira inverter de linha pretas para linhas brancas?

Giovanni5

Enviado 2019-11-11 08:46:33
felipesoares92

Para alterar o fator de leitura da linha, para se adequar a qualquer cor, é necessário ajustar o comando "#define LINETHRESHOLD 700", para um valor que se adeque a leitura do sensor sobre a linha da pista. Portanto, seria necessário realizar a leitura da linha apenas, e observar o valor lido pelo sensor para alterar corretamente o fator deste código.

Francois

Enviado 2019-11-11 15:39:40
felipesoares92

Complementando a resposta do Giovanni, se as cores do seu circuito forem invertidas, provavelmente será necessário também ajustar a lógica. Neste tutorial considera-se que a linha é preta, logo o sensor está sobre a linha quando o Arduino lê um valor acima de <LINETHRESHOLD>. Para uma linha branca, o sensor está sobre a ela quando o valor está abaixo de <LINETHRESHOLD>.

RicardoFerraz
date

Enviado 2018-05-30 20:21:31

Boa noite pessoal da Robocore, não róla de vocês fazerem um tutorial para controlar o seguidor de linha usando a técnica PID. estou pesquisando adoidado na net e não estou entendendo nada o que explicam.

Francois

Enviado 2018-06-01 10:10:06
RicardoFerraz

Está previsto disponibilizarmos um tutorial sobre o controle PID no microcontrolador, porém não para o kit de robótica, visto que é um assunto mais avançado.

RicardoFerraz
date

Enviado 2018-05-27 19:17:34

Uma coisa que descobri caso o falcon comece a girar feito um louco, pode ser que os pinos dos sensores estejam ligados errados. ;)

Francois

Enviado 2018-05-28 11:42:28
RicardoFerraz

Agradecemos o retorno, adicionamos o seu comentário na solução de problemas.

cristiane2002
date

Enviado 2017-09-11 17:29:04

*254-399
*887975
*273-315
*1017-1018
esse são oa valores

cristiane2002
date

Enviado 2017-09-11 17:31:02
cristiane2002

Coloque o seu robô sobre sua mesa. Quais sãos os valores lidos pelos dois sensores?Posicione-o sobre a folha com fita. Quais os valores lidos sobre a fita? E sobre a superfície branca?Com o robô ainda sobre a mesa, apague as luzes do ambiente ou cubra ele com um cobertor ou algo do gênero. O que acontece com os valores lidos? O que você acha que está causando isso?Mova o robô lentamente para a borda da mesa. Observe as leituras enquanto os sensores se aproximam da borda da mesa. Quais são os valores dos sensores quando eles estão fora da mesa?
eles estão nessa ordem.

Francois

Enviado 2017-09-11 18:23:14
cristiane2002

Os valores lidos estão dentro da faixa esperada. Na parte de "seguindo a linha", carregue o código deste item, deixe as rodas do robô sem contato com a superfície e mova manualmente os sensores sobre a linha, deixando os dois sobre ela, depois um de cada vez sobre e o outro fora (1, 2 e 3 na imagem). Lembre-se que os sensores devem ficar próximos à superfície para ter uma leitura válida. Nesse teste os dois motores devem girar na mesma velocidade quando os dois estão na linha, e um girar mais devagar do que o outro quando somente um sensor está na linha.

cristiane2002
date

Enviado 2017-09-09 18:58:32

está dando errado, meu codigo carrega certinho sem nenhum erro, só que quando coloco na folha com a fita, ele fica descontrolado fazendo circulos e só uma roda funciona a outra para, oq faço?

hallszombie
date

Enviado 2017-09-11 07:50:25
cristiane2002

Quando você fez o primeiro exercício do projeto "Exercício: Entendendo o comportamento dos Sensores", quais foram as leituras do sensor nas superfície branca e preta ?