IoT DevKit - 10. Central de Monitoramento por LoRaWAN

This tutorial is not available in English

Descrição

Neste denso e completo experimento mostramos como fazer a leitura dos sensores do IoT DevKit e enviar as informações lidas através da rede LoRaWAN provida pela ATC. Para isso adquirimos um plano ATC junto à plataforma de IoT ProIoT. O passo a passo é mostrado no vídeo e com a prática este processo acaba ficando natural. Note que mais uma vez as bibliotecas usadas no código nos poupam um tempo precioso e nosso código fica mais fácil de ser entendido. O domínio das funções das bibliotecas é fundamental para projetos como esse.

Após finalizar o experimento demosntrado no vídeo acima, você estará apto a enviar informações para uma plataforma de internet das coisas através da rede LoRaWAN. Isso é especialmente interessante para quando você precisa colocar objetos ligados à internet em campo, em locais onde você não possui redes WiFi ou mesmo em locais onde seu dispositivo não possui as credenciais desse tipo de rede. A rede LoRaWAN da ATC está presente em todas as capitais do Brasil e cada vez mais cidades passam a contar com essa tecnologia. Caso você se interesse pela tecnologia LoRaWAN, se aprofunde ainda mais lendo este tutorial.

Se tiver dúvidas sobre o código proposto abaixo, escreva no campo de comentários abaixo do código. Agora você conseguirá criar dispositivos de internet das coisas a partir de ideias e fazer a implementação facilmente!

Lista de Materiais

Lista completa de produtos

comprar

IoT DevKit - LoRaWAN

R$ 322,90 no PIX

Código

/************************************************
* RoboCore - IoT DevKit - LoRaWAN   
*
* Conecta a rede LoRaWAN e envia as leituras dos
* sensores a cada 5 minutos ou quando o botão
* for pressionado.
***********************************************/

#if !defined(ARDUINO_ESP32_DEV) // ESP32
#error Use this example with the ESP32
#endif

// --------------------------------------------------
// Libraries

// Incluimos todas as bibliotecas que usaremos neste codigo
#include "RoboCore_SMW_SX1276M0.h"
#include "DHT.h"
#include "RoboCore_MMA8452Q.h"
#include "ArduinoJson.h"
#include "HardwareSerial.h"
      
// --------------------------------------------------
// Variables

// Informamos ao ESP32 com quais pinos vamos nos conectar ao módulo LoRaWAN Bee
HardwareSerial LoRaSerial(2);
#define RXD2 16
#define TXD2 17
      
// Informamos ao ESP32 em quais pinos nossos sensores, botão e LEDs estão ligados
const int pinoDHT = 12;
const int pinoBotao = 4;
const int pinoLDR = 15;
const int statusLED = 13;
const int sendLED = 2;

// Inicializamos as variaveis que farao as leituras do botao e LDR
int estadoBotao = 0;
int valorLDR = 0;

// Criamos as instancias do DHT11, Acelerometro e LoRaWAN, que serao usadas no decorrer do codigo
DHT dht(pinoDHT, DHT11);
MMA8452Q acel;
SMW_SX1276M0 lorawan(LoRaSerial);

CommandResponse response;

// Inserimos as chaves APPEUI e APPKEY, conforme configurado na plataforma ProIoT
const char APPEUI[] = "0000000000000000";
const char APPKEY[] = "00000000000000000000000000000000";

// Criamos uma variavel que determinara de quanto em quanto tempo a informacao via LoRaWAN sera enviada
const unsigned long PAUSE_TIME = 300000; // [ms] (5 min)
unsigned long timeout;

// --------------------------------------------------
// Prototypes

void event_handler(Event);

// --------------------------------------------------
// --------------------------------------------------

void setup() {
      
  // Inicializamos a comunicacao serial entre ESP32 e computador
  Serial.begin(115200);
  Serial.println(F("--- SMW_SX1276M0 Join (OTAA) ---"));
  
  // Inicializamos a comunicacao serial entre ESP32 e modulo LoRaWAN Bee
  LoRaSerial.begin(115200, SERIAL_8N1, RXD2, TXD2);

  // Criamos uma variavel que ira "escutar" se vier algo do modulo LoRaWAN Bee
  lorawan.event_listener = &event_handler;
  Serial.println(F("Handler set"));
	
  // Resetamos o modulo LoRaWAN Bee para configura-lo
  delay(1000);
  lorawan.setPinReset(5);
  lorawan.reset();
	
  // Lemos o DEVEUI do modulo LoRaWAN Bee e mostramos no Monitor Serial
  char deveui[16];
  response = lorawan.get_DevEUI(deveui);
  if(response == CommandResponse::OK){
    Serial.print(F("DevEUI: "));
    Serial.write((uint8_t *)deveui, 16);
    Serial.println();
  } else {
    Serial.println(F("Error getting the Device EUI"));
  }

  // Configuramos a chave APPEUI no modulo e mostramos no Monitor Serial
  response = lorawan.set_AppEUI(APPEUI);
  if(response == CommandResponse::OK){
    Serial.print(F("Application EUI set ("));
    Serial.write((uint8_t *)APPEUI, 16);
    Serial.println(')');
  } else {
    Serial.println(F("Error setting the Application EUI"));
  }

  // Configuramos a chave APPKEY no modulo e mostramos no Monitor Serial
  response = lorawan.set_AppKey(APPKEY);
  if(response == CommandResponse::OK){
    Serial.print(F("Application Key set ("));
    Serial.write((uint8_t *)APPKEY, 32);
    Serial.println(')');
  } else {
    Serial.println(F("Error setting the Application Key"));
  }

  // Configuramos o modo de operacao do LoRaWAN Bee para OTAA
  response = lorawan.set_JoinMode(SMW_SX1276M0_JOIN_MODE_OTAA);
  if(response == CommandResponse::OK){
    Serial.println(F("Mode set to OTAA"));
  } else {
    Serial.println(F("Error setting the join mode"));
  }

  // Comecamos as tentativas para conexao na rede LoRaWAN da ATC
  Serial.println(F("Joining the network"));
  lorawan.join();
	
  // Configuramos os pinos como entrada ou saida, conforme sua funcao
  pinMode(pinoBotao, INPUT);
  pinMode(statusLED, OUTPUT);
  pinMode(sendLED, OUTPUT);
     
  // Inicializamos os sensores DHT11 e Acelerometro
  dht.begin();
  acel.init();
  
}

// --------------------------------------------------
// Criamos uma funcao para fazer a leitura dos dados, seja quando o codigo envia
// automtaicamente o payload para a plataforma, seja quando pressionamos o botao
      
void enviaDados(){

  // Acendemos o LED azul do ESP32 quando iniciamos a leitura e envio dos dados
  digitalWrite(sendLED, HIGH);

  // Fazemos a leitura do sensor de luminosidade LDR e mapeamos o valor lido
  valorLDR = analogRead(pinoLDR);
  valorLDR = map(valorLDR, 4095, 2500,0, 100);

  // Fazemos a leitura da temperatura e umidade
  float temperatura = dht.readTemperature();
  float umidade = dht.readHumidity();

  // Fazemos a leitura do acelerometro e multiplicamos os valores por 100, 
  // para torna-los valores inteiros e facilitar o envio para a plataforma
  acel.read();
  int x = acel.x * 100;
  int y = acel.y * 100;
  int z = acel.z * 100;

  // Criamos uma variavel JSON que ira conter os valores das variaveis
  DynamicJsonDocument json(JSON_OBJECT_SIZE(6));
	
  // Configuramos a variavel JSON com os Alias criados na plataforma ProIoT
  // e salvamos em cada componente o respectivo valor da variavel lida
  json["T"] = temperatura;
  json["U"] = umidade;
  json["L"] = valorLDR;
  json["X"] = x;
  json["Y"] = y;
  json["Z"] = z;

  // Criamos uma String chamada payload que ira conter todas as informacoes do JSON
  String payload = "";
  serializeJson(json, payload);

  Serial.print("Valores enviados: ");
  Serial.println(payload);

  // Enviamos todas as informações via LoRaWAN
  lorawan.sendT(1, payload);

  // Apagamos o LED azul do ESP32 quando terminamos de enviar
  digitalWrite(sendLED, LOW);
  
}

// --------------------------------------------------

void loop() {
  // "Escutamos" se algo vem do modulo LoRaWAN Bee
  lorawan.listen();

  // Se esta conectado a rede entra nesta rotina
  if(lorawan.isConnected()){
	
    // Faz a leitura do botao e acessa a funcao de envio de dados
    estadoBotao = digitalRead(pinoBotao);
    if(estadoBotao == LOW){
      delay(30);
      estadoBotao = digitalRead(pinoBotao);
      enviaDados();
      while(digitalRead(pinoBotao) == LOW){
        // Espero soltar o botao
      }
    }
    
   	// A cada PAUSE_TIME milisegundos, acessamos a funcao de envio de dados
    if(timeout < millis()){

      enviaDados();
      
      timeout = millis() + PAUSE_TIME;
    }
  } else {
    // Se nao conseguir se conectar a rede LoRaWAN, imprime no 
    // Monitor Serial "." a cada 5 segundos
    if(timeout < millis()){
      Serial.println('.');
      timeout = millis() + 5000; // 5 s
    }
  }
}

// --------------------------------------------------
// --------------------------------------------------

// Verifica o que foi recebido do modulo LoRaWAN Bee e, se o que foi recebido
// for um evento do tipo JOINED, informa que se conectou no Monitor Serial e 
// acende o LED do IoT DevKit
void event_handler(Event type){
  if(type == Event::JOINED){
    Serial.println(F("Joined"));
    digitalWrite(statusLED, HIGH);
  }
}

​x
 
/************************************************
* RoboCore - IoT DevKit - LoRaWAN   
*
* Conecta a rede LoRaWAN e envia as leituras dos
* sensores a cada 5 minutos ou quando o botão
* for pressionado.
***********************************************/
​
#if !defined(ARDUINO_ESP32_DEV) // ESP32
#error Use this example with the ESP32
#endif
​
// --------------------------------------------------
// Libraries
​
// Incluimos todas as bibliotecas que usaremos neste codigo
#include "RoboCore_SMW_SX1276M0.h"
#include "DHT.h"
#include "RoboCore_MMA8452Q.h"
#include "ArduinoJson.h"
#include "HardwareSerial.h"
      
// --------------------------------------------------
// Variables
​
// Informamos ao ESP32 com quais pinos vamos nos conectar ao módulo LoRaWAN Bee
HardwareSerial LoRaSerial(2);
#define RXD2 16
#define TXD2 17
      
// Informamos ao ESP32 em quais pinos nossos sensores, botão e LEDs estão ligados
const int pinoDHT = 12;
const int pinoBotao = 4;
const int pinoLDR = 15;
const int statusLED = 13;
const int sendLED = 2;
​
// Inicializamos as variaveis que farao as leituras do botao e LDR
int estadoBotao = 0;
int valorLDR = 0;
​
// Criamos as instancias do DHT11, Acelerometro e LoRaWAN, que serao usadas no decorrer do codigo
DHT dht(pinoDHT, DHT11);
MMA8452Q acel;
SMW_SX1276M0 lorawan(LoRaSerial);
​
CommandResponse response;
​
// Inserimos as chaves APPEUI e APPKEY, conforme configurado na plataforma ProIoT
const char APPEUI[] = "0000000000000000";
const char APPKEY[] = "00000000000000000000000000000000";
​
// Criamos uma variavel que determinara de quanto em quanto tempo a informacao via LoRaWAN sera enviada
const unsigned long PAUSE_TIME = 300000; // [ms] (5 min)
unsigned long timeout;
​
// --------------------------------------------------
// Prototypes
​
void event_handler(Event);
​
// --------------------------------------------------
// --------------------------------------------------
​
void setup() {
      
  // Inicializamos a comunicacao serial entre ESP32 e computador
  Serial.begin(115200);
  Serial.println(F("--- SMW_SX1276M0 Join (OTAA) ---"));
  
  // Inicializamos a comunicacao serial entre ESP32 e modulo LoRaWAN Bee
  LoRaSerial.begin(115200, SERIAL_8N1, RXD2, TXD2);
​
  // Criamos uma variavel que ira "escutar" se vier algo do modulo LoRaWAN Bee
  lorawan.event_listener = &event_handler;
  Serial.println(F("Handler set"));
    
  // Resetamos o modulo LoRaWAN Bee para configura-lo
  delay(1000);
  lorawan.setPinReset(5);
  lorawan.reset();
    
  // Lemos o DEVEUI do modulo LoRaWAN Bee e mostramos no Monitor Serial
  char deveui[16];
  response = lorawan.get_DevEUI(deveui);
  if(response == CommandResponse::OK){
    Serial.print(F("DevEUI: "));
    Serial.write((uint8_t *)deveui, 16);
    Serial.println();
  } else {
    Serial.println(F("Error getting the Device EUI"));
  }
​
  // Configuramos a chave APPEUI no modulo e mostramos no Monitor Serial
  response = lorawan.set_AppEUI(APPEUI);
  if(response == CommandResponse::OK){
    Serial.print(F("Application EUI set ("));
    Serial.write((uint8_t *)APPEUI, 16);
    Serial.println(')');
  } else {
    Serial.println(F("Error setting the Application EUI"));
  }
​
  // Configuramos a chave APPKEY no modulo e mostramos no Monitor Serial
  response = lorawan.set_AppKey(APPKEY);
  if(response == CommandResponse::OK){
    Serial.print(F("Application Key set ("));
    Serial.write((uint8_t *)APPKEY, 32);
    Serial.println(')');
  } else {
    Serial.println(F("Error setting the Application Key"));
  }
​
  // Configuramos o modo de operacao do LoRaWAN Bee para OTAA
  response = lorawan.set_JoinMode(SMW_SX1276M0_JOIN_MODE_OTAA);
  if(response == CommandResponse::OK){
    Serial.println(F("Mode set to OTAA"));
  } else {
    Serial.println(F("Error setting the join mode"));
  }
​
  // Comecamos as tentativas para conexao na rede LoRaWAN da ATC
  Serial.println(F("Joining the network"));
  lorawan.join();
    
  // Configuramos os pinos como entrada ou saida, conforme sua funcao
  pinMode(pinoBotao, INPUT);
  pinMode(statusLED, OUTPUT);
  pinMode(sendLED, OUTPUT);
     
  // Inicializamos os sensores DHT11 e Acelerometro
  dht.begin();
  acel.init();
  
}
​
// --------------------------------------------------
// Criamos uma funcao para fazer a leitura dos dados, seja quando o codigo envia
// automtaicamente o payload para a plataforma, seja quando pressionamos o botao
      
void enviaDados(){
​
  // Acendemos o LED azul do ESP32 quando iniciamos a leitura e envio dos dados
  digitalWrite(sendLED, HIGH);
​
  // Fazemos a leitura do sensor de luminosidade LDR e mapeamos o valor lido
  valorLDR = analogRead(pinoLDR);
  valorLDR = map(valorLDR, 4095, 2500,0, 100);
​
  // Fazemos a leitura da temperatura e umidade
  float temperatura = dht.readTemperature();
  float umidade = dht.readHumidity();
​
  // Fazemos a leitura do acelerometro e multiplicamos os valores por 100, 
  // para torna-los valores inteiros e facilitar o envio para a plataforma
  acel.read();
  int x = acel.x * 100;
  int y = acel.y * 100;
  int z = acel.z * 100;
​
  // Criamos uma variavel JSON que ira conter os valores das variaveis
  DynamicJsonDocument json(JSON_OBJECT_SIZE(6));
    
  // Configuramos a variavel JSON com os Alias criados na plataforma ProIoT
  // e salvamos em cada componente o respectivo valor da variavel lida
  json["T"] = temperatura;
  json["U"] = umidade;
  json["L"] = valorLDR;
  json["X"] = x;
  json["Y"] = y;
  json["Z"] = z;
​
  // Criamos uma String chamada payload que ira conter todas as informacoes do JSON
  String payload = "";
  serializeJson(json, payload);
​
  Serial.print("Valores enviados: ");
  Serial.println(payload);
​
  // Enviamos todas as informações via LoRaWAN
  lorawan.sendT(1, payload);
​
  // Apagamos o LED azul do ESP32 quando terminamos de enviar
  digitalWrite(sendLED, LOW);
  
}
​
// --------------------------------------------------
​
void loop() {
  // "Escutamos" se algo vem do modulo LoRaWAN Bee
  lorawan.listen();
​
  // Se esta conectado a rede entra nesta rotina
  if(lorawan.isConnected()){
    
    // Faz a leitura do botao e acessa a funcao de envio de dados
    estadoBotao = digitalRead(pinoBotao);
    if(estadoBotao == LOW){
      delay(30);
      estadoBotao = digitalRead(pinoBotao);
      enviaDados();
      while(digitalRead(pinoBotao) == LOW){
        // Espero soltar o botao
      }
    }
    
    // A cada PAUSE_TIME milisegundos, acessamos a funcao de envio de dados
    if(timeout < millis()){
​
      enviaDados();
      
      timeout = millis() + PAUSE_TIME;
    }
  } else {
    // Se nao conseguir se conectar a rede LoRaWAN, imprime no 
    // Monitor Serial "." a cada 5 segundos
    if(timeout < millis()){
      Serial.println('.');
      timeout = millis() + 5000; // 5 s
    }
  }
}
​
// --------------------------------------------------
// --------------------------------------------------
​
// Verifica o que foi recebido do modulo LoRaWAN Bee e, se o que foi recebido
// for um evento do tipo JOINED, informa que se conectou no Monitor Serial e 
// acende o LED do IoT DevKit
void event_handler(Event type){
  if(type == Event::JOINED){
    Serial.println(F("Joined"));
    digitalWrite(statusLED, HIGH);
  }
}

Comments

To make comments you must be logged in. Login.

You are not registered yet? Register Now!

sourientjr1
date

Sent 2022-03-31 13:44:35

Mestre Giovani, qual plataforma você me indica para praticar com a devboard já que a usada aqui não dá mais? Abração a todos por aí!

Giovanni5

Sent 2022-03-31 14:09:43
sourientjr1

Existem diversas plataformas IoT disponíveis que você pode testar com o DevKit, como, por exemplo a The Things Network (https://www.thethingsnetwork.org/country/brazil/), porém só temos tutoriais de uso para a ProIoT, e pelo que testamos todos os tutoriais do material do Kit ainda estão funcionando corretamente com a plataforma mostrada.

robsonpski
date

Sent 2022-02-14 13:20:42

Boa tarde pessoal, tem com o pegar o RSSI do modulo da lorawan? Queria ter estatisticas de forca de sinal

Giovanni5

Sent 2022-02-14 15:31:26
robsonpski

Você pode utilizar a função <get_RSSI()> para coletar o RSSI do módulo à rede, porém ele só deve retornar um valor ao receber um "Downlink" da plataforma.

rbastos.vix
date

Sent 2021-10-25 14:08:13

boa tarde amigos, podem me ajudar, não consigo comprar o plano de conexão da ProIoT.
tem alguma alternativa?

Giovanni5

Sent 2021-10-25 14:49:46
rbastos.vix

Infelizmente a ProIoT decidiu recentemente encerrar a comercialização dos planos ATC (https://talk.proiot.com.br/t/fim-dos-planos-lorawan/363), portanto infelizmente não é mais possível adquiri-los. Planos ATC que já haviam sido adquiridos anteriormente, permanecerão ativos até o período de renovação, quando também serão cancelados. Ainda estamos buscando alternativas robustas para substituição.

piccininiconsultoria
date

Sent 2021-09-02 12:39:51

Como você comenta, acho que segurei o botão à esquerda da entrada USB por longo tempo. Talvez isto tenha disparado o reset de fábrica.
Vamos lá. Segui a sua orientação e realmente estava 6, mudei para 1, mas o DevEUI permanece em zeros:

09:52:12.190 -> 0000000000000000
09:52:12.190 -> 
09:52:12.190 -> <OK>
09:52:39.212 -> 6
09:52:39.212 -> 
09:52:39.212 -> <OK>
09:53:11.359 -> *
09:53:11.359 -> Boot by CPU 
09:53:11.359 -> OTAA
09:53:11.450 -> AU915
09:53:11.450 -> Boot completed
09:53:11.450 -> 
09:53:11.450 -> F/W VERSION : 0.16
09:53:11.450 -> DEVICE EUI : 0000000000000000
09:53:49.262 ->

piccininiconsultoria
date

Sent 2021-09-02 13:06:44
piccininiconsultoria

Com os comandos dados, ficou perfeito....Funcionando novamente. Muito Obrigado

Giovanni5

Sent 2021-09-02 13:12:22
piccininiconsultoria

piccininiconsultoria ficamos felizes que tenha conseguido reconfigurar o módulo, e que ele esteja funcionando corretamente de novo. Qualquer dúvida entre em contato.

piccininiconsultoria
date

Sent 2021-09-02 11:49:40

Como você comenta, acho que segurei o botão à esquerda da entrada USB por longo tempo. Talvez isto tenha disparado o reset de fábrica.
Vamos lá. Segui a sua orientação e realmente estava 6, mudei para 1, mas o DevEUI permanece em zeros:

09:52:12.190 -> 0000000000000000
09:52:12.190 -> 
09:52:12.190 -> <OK>
09:52:39.212 -> 6
09:52:39.212 -> 
09:52:39.212 -> <OK>
09:53:11.359 -> *
09:53:11.359 -> Boot by CPU 
09:53:11.359 -> OTAA
09:53:11.450 -> AU915
09:53:11.450 -> Boot completed
09:53:11.450 -> 
09:53:11.450 -> F/W VERSION : 0.16
09:53:11.450 -> DEVICE EUI : 0000000000000000
09:53:49.262 ->

Giovanni5

Sent 2021-09-02 12:05:02
piccininiconsultoria

Agora será necessário reconfigurar o DEVEUI do módulo. Para isso envie o comando <AT+DEVEUI codigo>, trocando a palavra "código" pelo DEVEUI que está descrito na etiqueta do seu módulo. Feito isso, apenas verifique se os canais do módulo estão corretamente habilitados como mostrado no outro tutorial, e o módulo já deve estar pronto para ser utilizado neste projeto novamente.

piccininiconsultoria
date

Sent 2021-09-02 09:14:38

hoje as 08:39 inicializei o device com o Log abaixo:

08:39:22.112 -> DevEUI: 50f8..............6e
08:39:23.086 -> Application EUI set (fe201c0b97b462df)
08:39:24.115 -> Application Key set (0c9ecc4d7a93748d0da7626c78a2c4a1)
08:39:26.298 -> Mode set to OTAA
08:39:26.345 -> Joining the network

Fiz novo reset e apareceu:

08:51:45.156 -> DevEUI: 0000000000000000
08:51:46.244 -> Application EUI set (fe201c0b97b462df)
08:51:47.144 -> Application Key set (0c9ecc4d7a93748d0da7626c78a2c4a1)
08:51:49.382 -> Mode set to OTAA
08:51:49.382 -> Joining the network

Alguma razão para o DevEUI estar zero

Giovanni5

Sent 2021-09-02 09:40:35
piccininiconsultoria

Como o reset do conjunto foi feito? É possível que, por conta de um reset indevido o módulo tenha retornado para os seus padrões de fábrica, portanto volte para o código de interface com o módulo (https://www.robocore.net/tutoriais/iot-devkit-introducao-lorawan), envie o comando <AT+REGION>, e observe o resultado. Se o módulo retornar "6", é sinal que de fato ele retornou para o padrão de fábrica (região coreana), e portanto será necessário voltá-lo para o padrão brasileiro (<AT+REGION 1> - o mesmo que o australiano), e reconfigurar o módulo.

marciofernandoflores
date

Sent 2020-11-26 15:03:39

Fiz  as configurações mas não consigo me conectar. Como devo proceder ?
15:51:40.279 -> Application Key set (00000000000000000000000000000000)
15:51:42.478 -> Mode set to OTAA
15:51:42.478 -> Joining the network
15:51:42.524 -> .
15:51:47.489 -> .
15:51:52.524 -> .
15:51:57.540 -> .
15:52:02.551 -> .
15:52:07.564 -> .
15:52:12.538 -> .

Giovanni5

Sent 2020-11-26 15:19:52
marciofernandoflores

Pelo pequeno trecho da resposta comentada, dá pra ver que o "Application Key" ainda está "zerado", provavelmente você se esqueceu de alterar esse parâmetro no código antes de carregá-lo para a placa. Portanto altere a declaração das variáveis "APPEUI" e "APPKEY" com as chaves de "Application EUI" e "Application Key" geradas na plataforma, respectivamente.